Labeled data messes up ListPlot

Question

I am having problems with the new labeling functions Labeled when used in ListPlot or any of its sibblings. Labeled data can only be shown with the full range. If I apply a partial PlotRange the plots is messed up:

data = Table[{i, Sin@i}, {i, -50, 50}];

ListLinePlot[Labeled[data, "data"], PlotTheme -> "Frame"]

ListLinePlot[Labeled[data, "data"], PlotRange -> {{20, 50}, All},  PlotTheme -> "Frame"] 

Show doesn't help, as it sometimes does in similar cases. It just adds to the mess:

Show[ListLinePlot[Labeled[data, "data"]], PlotRange -> {{20, 50}, All}]

Consistently, the behavior is the same when using Callout instead:

Of course I copuld pre-filter my data, but the whole point of PlotRange is not having to do it. I assume this is a bug. Does anybody know of an easy workaround?

Edit:

This is on Windows 10, Version 11.2

Answer 1

The main problem with restricting the plot range, while having labels that exist outside of the plot range is that the option PlotRangeClipping is not smart enough to clip only the data and not the labels. As a workaround, one can use the Mesh options of ListLinePlot to hide the portion of the plot that shouldn't be seen. This way we don't need to use PlotRangeClipping->True to restrict the plot. Here's an example:

ListLinePlot[
    {Labeled[data, "data"]},
    PlotTheme -> "Frame",
    PlotRange -> {{20, 50}, All},
    Mesh -> {{{20}, {50}}, {}},
    MeshShading -> {None, Opacity[1]}
]

Answer 2

My experience with Mathematica tells me to solve the problem by trimming the data before plotting it, rather than plotting all the data but then restricting the viewport. One way to do it is

data = Table[{i, Sin @ i}, {i, -50, 50}];
ListLinePlot[Labeled[Select[data, 20 <= First[#] <= 50 &], "data"], PlotTheme -> "Frame"]

But it might even be easier to just generate a new data set.

trimedData = Table[{i, Sin @ i}, {i, 20, 50}];
ListLinePlot[Labeled[trimedData, "data"], PlotTheme -> "Frame"]

Both plots are same.