How can I display points with their coordinates?

Question

Garfield = {
    Graphics[Line[{{1,3},{1,5},{2,6},{2,9},{3,10},{4,10},{5,9},{5.5,8},{6,9},{7,10},{8,10},{9,9},{9,6},{10,5},{10,3},{9,2},{7,1},{4,1},{2,2},{1,3}}]],
    Graphics[Line[{{2.5,3.5},{3,4},{3.5,3},{4.5,3},{5.5,4},{6.5,3},{7.5,3},{8,4},{8.5,3.5}}]],
    Graphics[Line[{{5,4},{6,4},{6,4.5},{5,4.5},{5,4}}]],
    Graphics[Line[{{8.5,3.5},{9,3.5},{9,4.5},{2,4.5},{2,3.5},{2.5,3.5}}]],
    Graphics[Line[{{3,4.5},{5,4.5},{5,7},{3,7},{3,4.5}}]],
    Graphics[Line[{{6,4.5},{8,4.5},{8,7},{6,7},{6,4.5}}]],
    Graphics[Line[{{4,5},{4.5,5},{4.5,6},{4,6},{4,5}}]],
    Graphics[Line[{{6.5,5},{7,5},{7,6},{6.5,6},{6.5,5}}]],
    Graphics[Epilog -> {PointSize[Large], Red, {1, 3}}]
};


Show[Garfield, Frame -> True]

It displays fine, but with no Point in red. How do I get each point to display and with their coordinates like this?

Additionally

It would seem a bit excessive to show (x,y) for all points, could we make something more flexible like,

...
...
Graphics[Line[{showp{8.5,3.5},{9,3.5},{9,4.5},showp{2,4.5},{2,3.5},{2.5,3.5}}]],
...
...

where we use showp to indicate we want to show these points in that particular segment of drawing?

Thanks.

Answer 1

Callout can help you position the labels. I will let you experiment with the options so that the display gets right, but here is a start:

coords = {{1, 3}, {1, 5}, {2, 6}, {2, 9}, {3, 10}, {4, 10}, {5, 9}, {5.5, 8}, {6, 9}, {7, 10}, {8, 10}, {9, 9}, {9, 6}, {10, 5}, {10, 3}, {9, 2}, {7, 1}, {4, 1}, {2, 2}};
callouts = Callout[#, #] & /@ coords;
ListPlot[callouts, Prolog -> Line[Append[coords, {1, 3}]], ImageSize -> 600]

Answer 2

I don't like the idea of displaying the coordinates alongside the points. Positioning them is tricky and the drawing quickly becomes very cluttered. So I suggest labeling the points with tooltips that will only appear when the mouse cursor moves a point.

The necessary modification to your code is simple

Garfield = 
  {Graphics[Line[{{1, 3}, {1, 5}, {2, 6}, {2, 9}, {3, 10}, {4, 10}, {5, 9}, {5.5, 8}, {6, 9}, {7, 10}, {8, 10}, {9, 9}, {9, 6}, {10, 5}, {10, 3}, {9, 2}, {7, 1}, {4, 1}, {2, 2}, {1, 3}}]], 
   Graphics[Line[{{2.5, 3.5}, {3, 4}, {3.5, 3}, {4.5, 3}, {5.5, 4}, {6.5, 3}, {7.5, 3}, {8, 4}, {8.5, 3.5}}]], 
   Graphics[Line[{{5, 4}, {6, 4}, {6, 4.5}, {5, 4.5}, {5, 4}}]], 
   Graphics[Line[{{8.5, 3.5}, {9, 3.5}, {9, 4.5}, {2, 4.5}, {2, 3.5}, {2.5, 3.5}}]], 
   Graphics[Line[{{3, 4.5}, {5, 4.5}, {5, 7}, {3, 7}, {3, 4.5}}]], 
   Graphics[Line[{{6, 4.5}, {8, 4.5}, {8, 7}, {6, 7}, {6, 4.5}}]], 
   Graphics[Line[{{4, 5}, {4.5, 5}, {4.5, 6}, {4, 6}, {4, 5}}]], 
   Graphics[Line[{{6.5, 5}, {7, 5}, {7, 6}, {6.5, 6}, {6.5, 5}}]]};

pts = {{1, 3}, {3, 4}};

Show[
  Garfield,
  Graphics @ Tooltip[{PointSize[Large], Red, Point[#]}, #] & /@ pts,
  Frame -> True]

Of course, you need to modify pts to be the list of all the points you want to show.

If you don't like my solution using tooltips, which is quick and easy, you might want to look at a more elaborate solution I offer here that will allow you to put the coordinates anywhere you like.

Note: Graphics does not accept the Epilog option because it is never needed. Epilog is for Plot and its relatives.