How to use Callout for points on Graphics objects?

Question

Callout is a relatively recent functionality that is pretty useful to add custom labels to points and plots. A minimal example of it being used in ListPlot is

ListPlot[{{0, 0}, Callout[{1, 1}, "Cool label"], {2, 2}}]

What I am looking for is the same exact functionality, but for points in Graphics objects. I'm looking for a good way to do the above with points drawn with something like

Graphics[{Point@{{0,0},{1,1},{2,2}}}]

Unfortunately, naive guesses such as Point@Callout[{0,0},"ASD"], Callout[Point@{0,0}] don't seem to work. The documentation of Callout also doesn't mention any example using Graphics object, which makes me thing the functionality simply isn't implemented for Graphics.

Is there a good way to still do the above? Of course, I could "hack it" by having the callout drawn in a ListPlot, and then put in the embedding Graphics via Show. Something like:

Show[
  Graphics[
    Point@{0, 0},
    PlotRange -> ConstantArray[{-1, 1}, 2], Frame -> True
  ],
  ListPlot[
    {Callout[{0, 0}, "Cool label"]},
    Axes -> False, PlotStyle -> Directive[Opacity@0]
  ]
]

does what it should, but isn't exactly "nice". Is there a better way to achieve this? It doesn't have to be a solution with Callout; similar functionality using something else would also be fine. As long as it doesn't require manually drawing and positioning label and connecting line.

Answer 1

Please note that with Show you don't embed ListPlot graphics into a Graphics object, but combine both of them into a single Graphics object.

Positioning of the callouts by ListPlot depends on AspectRatio, PlotRange, PlotRangePadding and the style settings for the plot marker. By setting the target values of these options explicitly, you get the desired "nice" appearance:

Show[ListPlot[{Callout[{0, 0}, "Cool label"]},
   AspectRatio -> Automatic,
   PlotRange -> ConstantArray[{-1, 1}, 2], PlotRangePadding -> None,
   PlotStyle -> AbsolutePointSize[2]] /. _Point -> Nothing,
 Graphics[Point@{0, 0},
  PlotRange -> ConstantArray[{-1, 1}, 2]],
 Frame -> True, Axes -> False]

In principle, you could write your own "callout primitive" using Inset as follows:

Clear[callout]
callout[point_, label_, markerSize_ : 2] := 
 Inset[ListPlot[{Callout[{0, 0}, label]}, ImageSize -> All, 
    Axes -> False, AlignmentPoint -> {0, 0}, 
    PlotStyle -> AbsolutePointSize[markerSize]] /. _Point -> Nothing, 
  point]

Examples of use:

Graphics[{Point[{{1, 1}}], callout[{1, 1}, "Cool label", 1]}, 
 Frame -> True]

Graphics[{Point[{{1, 1}}]}, Frame -> True, 
 Epilog -> callout[{1, 1}, "Cool label", 1]]