Color ramp banding in PDFKit when exporting Raster image Inset to PDF

Question

Here I produce a Raster image with large uniformly colored rectangles and put it in an Inset:

With[{n = 5},
 Graphics[Inset[
   Graphics[Raster[
     {Map[
       List @@ ColorConvert[ColorData["LakeColors"][#], 
          RGBColor] &, (Range[n - 1] - 1)/(n - 2)]}
     ]],
   Automatic, Automatic, {.45, .5}
   ]
  ]
 ]

Now export this to PDF:

Export["p.pdf", %]

The uniform regions have been replaced by a series of discrete bands that seem to try an interpolate between the rectangles. This happens if I choose fewer rectangles too (e.g., n = 3).

If I generate the same thing without using Raster, the exported PDF looks fine - e.g., try this:

With[{n = 5},
 Graphics[Inset[
   Graphics[
    MapIndexed[{ColorData["LakeColors"][#], 
       Translate[Rectangle[], {#2[[1]], 0}]} &, (Range[n - 1] - 
        1)/(n - 2)]
    ]
   ,
   Automatic, Automatic, {.45, .5}
   ]
  ]
 ]

So it's the conversion of the rasterized image in Export that's responsible for this effect. Interestingly, one can work around this (on Mac) by selecting the graphic, going to Edit > Copy As > PDF and pasting the result into Preview.

Although I have some workarounds now, it still seems mysterious to me why this banding effect happens with Raster. And it would of course be nice if someone knew how to use Raster in an Inset inside a Graphics without triggering the effect that causes the blocks of the raster to lose their uniform color.

Also - the arguments to Inset can be left out (in particular the scaling {.45, .5}). But it seemed to me that this problem didn't always happen with Raster, and that it probably has something to do with the size of the bitmap being scaled up relative to some assumed coordinate system used in Export.

Answer 1

This issue seems to affect all PDFKit based viewers on OS X, but it doesn't appear to point to anything intrinsically wrong with Mathematica's PDF export. A work-around that allows you to view the exported PDF without color bands in PDFKit viewers such as Preview would be to use the following command when creating the PDF in Mathematica:

Export["py.pdf", 
 p /. Graphics[Raster[i__]] :> 
   Image@Graphics[Raster[i]]]

Alternatively, if you know exactly where the Raster is being created, you may as well do the conversion immediately at that point. Then my example code above would have to be modified as follows:

With[{n = 5},
 Graphics[Inset[
   Image@Graphics[Raster[
      {Map[
        List @@ ColorConvert[ColorData["LakeColors"][#], 
           RGBColor] &, (Range[n - 1] - 1)/(n - 2)]}
      ]]]
  ]
 ]

After doing this, I see no more trace of the discrete bands.

Edit Originally I had inserted ColorConvert but then realized it's simply the conversion to Image that is required to make it work.

Edit 2

To make this more generally applicable: whenever your exported PDF shows banding in gradients, you could try to export the plot (let's call it plot) using this command:

Export["plot.pdf", plot /. Raster[i__] :>
 Raster@ImageData@Image@Graphics[Raster[i]]]

Edit 3

This is an old post, but in the meantime I encountered similar issues in many other contexts and came up with a different work-around which also applies here:

rasterTrick[plot_] := 
 Show[plot, 
  Prolog -> {Opacity[0], Texture[{{{0, 0, 0, 0}}}], 
    VertexTextureCoordinates -> {{0, 0}, {1, 0}, {1, 1}}, 
    Polygon[{{0, 0}, {.1, 0}, {.1, .1}}]}]

Export["p.pdf", plot // rasterTrick]

The function rasterTrick was recently useful in answering this question (where you can also find a link to further explanations of how it works): Export MatrixPlot graphics to PDF