Exporting Grid as PDF resizes the graphic. How to fix it?

Question

I am attempting to export some figures and plots for a publication, and I decided to export the figures as the size they need to be without rescaling them. This would ensure that fonts and linewidths are all consistent between the figures.

I also wish to export the figures as PDF, since that is a vectorized format.

However, I have come across an issue. Some of my plots are wrapped in a Grid. I have discovered that these plots when rendered as a PDF are smaller than an equivalent without the Grid. This issue does not occur when I use PNG format - the Grid and no-Grid plots are the same scale in PNG, but different scales in PDF. I note that using ImageSizeMultipliers (as described here) has no effect.

The following code shows my issue with a minimal working example:

square1 = Graphics[Rectangle[], ImageSize -> 200]
square2 = Grid[{{square1}}]
Export["square1.pdf", square1];
Export["square2.pdf", square2];
Export["square1.png", square1];
Export["square2.png", square2];

(The four exported figures, rendered on the same page and labeled.)

Because the rescaling depends on the export format, this implies it is something wrong with the export format rather than the Grid or Graphics specifically.

Is there any way I can make Grid export as a PDF without it being rescaled so that it matches the scale of my other graphics?

If it is relevant, I am using Mathematica version 11.2.0.0 on Windows 10.

Answer 1

This has been a long-term annoyance when exporting graphics from Mathematica.

The root cause is that non-Graphics notebook objects are exported in the "Printout" environment, which downscales to 80% by default.

It is discussed here and in the MaTeX tutorial titled "Preparing Figures to Size".

The symptom

If expr is not Graphics or Graphics3D, then Export["file.pdf", expr] will be downscaled to 80% of the original size.

Note that anything with a legend has head Legended, so it used to be downscaled too in earlier versions. This seems to have been fixed specifically for Legended in version 12.0.

Before version 12.0, this was exported at normal size:

Plot[{Sin[x], Cos[x]}, {x, 0, 2 Pi}]

This was exported at 80% size:

Plot[{Sin[x], Cos[x]}, {x, 0, 2 Pi}, PlotLegends -> "Expressions"]

Now this is fixed with Legended objects, but it still persists with things like Row, Column, Grid, Framed, etc. (which could be wrapping graphics).

The workaround

Set Mathematica to "print" in the "Working" environment instead of the "Printing" environment.

This can be done using

SetOptions[$FrontEndSession, PrintingStyleEnvironment -> "Working"]

The setting will be cleared once the front end is restarted (it is not sufficient to restart the kernel).

Notes

Note that there are two effects from Row/Column/Grid.

One is that all graphics with a "soft" size specification such as ImageSize -> Medium are downscaled even on-screen to fit the Grid better. This can be prevented by using an exact size specification such as ImageSize -> 200 (as you did). Medium is normally of size ImageSize -> 360.

The other, separate effect is that the are downscaled only when exported to PDF/PostScript or printed. This we work around by setting PrintingStyleEnvironment -> "Working".