Exporting to PDF with correct size and resolution

Question

I am trying to export a GraphicsGrid to a PDF such that the PDF has a size of 8x10 inches and a resolution of 300 dpi. Here is what I have done:

1. Create the graphics grid with ImageSize->Full to get all the images placed in the grid correctly.

2. Rasterize it to RasterSize 300{8,10}.

grid = Rasterize[
  GraphicsGrid[{
    {fiberAndReferencePlot}, 
    {transmissionPlot},
    {summaryPlotRadians}
   }, 
   ImageSize -> Full
   ], 
  RasterSize -> 300 {8, 10}
  ]

3. Export it to the correct size 8x10.

Export["Grid.pdf", grid, ImageSize -> 72 {8, 10}]

When I look at the PDF with Photoshop, it tells me that the image size in pixels is 2400x3000, which is correct. But the size in inches is 6.3 x 7.875, which is not the 8 x 10 I expected.

Can anyone tell me how to do this properly?

EDIT:

Here is something else I tried. I create a rasterized image of the desired pixel dimensions. Then I export telling export the ImageResolution is 300. I hoped that export would then respect the size of the raster, and calculate an image size in inches based on the specified image resolution.

im1 = Plot[Sin[x], {x, 0, 4 Pi}, Frame -> True, PlotLabel -> "Sin(x)",
    FrameLabel -> {"Angle", "Value"}];

g = GraphicsGrid[{{im1}, {im1}, {im1}}];

gr = Rasterize[g, RasterSize -> 1500];

Dimensions@ImageData@gr

(* {2696,1500,3} *)

pdf = Export["gr.pdf", gr, ImageResolution -> 300];

When I look at the exported PDF with Photoshop, it tells me the PDF has a size of 1080 x 1941 pixels in 3.6 x 6.47 inches. This does not seem to have any relationship to what I wanted.

What I am trying to do should be very simple. I want to take a graphic displayed on the screen and export it at a specific resolution and image size.

Answer 1

Well exporting graphics from Mathematica is always a painful process. The program is not designed well for outputting graphics/generating complex plots easily at least when compared to something like Pythons matplotlib package. After this short rant a view practical suggestions.

1. Set the printing environment to Working (either using the front end: File->Print Settings->Printing Environment->Working or using SetOptions[$FrontEndSession,PrintingStyleEnvironment -> "Working"]). This way the plots inside the notebook at least somewhat resemble the ones exported and one can start tweaking.
2. Use cmToPt[cm_]:=QuantityMagnitude@UnitConvert[Quantity[cm,"cm"],"PrinterPoints"] or inchesToPt[inches_]:=QuantityMagnitude@UnitConvert[Quantity[inches,"Inches"],"PrinterPoints"] to convert from to physical units.
3. Use ImageSize and ImageResolution for rasterized PDF-export.

After those rather general remarks here a possible solution to OPs specific question:

im1 = Plot[Sin[x], {x, 0, 4 Pi}, Frame -> True, PlotLabel -> "Sin(x)",FrameLabel -> {"Angle", "Value"}];
g = GraphicsGrid[{{im1}, {im1}, {im1}}];
gr = Rasterize[g, ImageResolution -> 300, ImageSize -> inchesToPt[8]]
pdf = Export["gr_300.pdf", gr]

ImageData[gr] // Dimensions returns {4313, 2400, 3} which is consistent with the specified width of 8 inches at a resolution of 300pt per inch. The exported PDF has a size of 8 times 14.4 inches and when I import the PDF into a graphics program (making sure to import the image only) I get the 2400 times 4313 Pixel image size.

For the GraphicsGrid in question this solution works surprisingly well but in my experience working with more complicated (composite) graphics (including Legends, more exotic plots, ...) this usually is not the case when exporting graphics (especially vector graphics) from Mathematica. One shortcoming of the current answer is that the aspect ratio of the image is basically given by g. It might be possible to get RasterSize to work but the documentation states that RasterSize overwrites ImageResolution which to me seems necessary when exporting rasterized content to PDF.