Export high resolution figure causes missing ticks

Question

Bug persisting through 11.3

---

I understand that Mathematica has a bug when exporting images. The ticks are scaled not correctly when exporting at high resolution. For example: when you do:

Export["xx.png", plot, ImageResolution -> 360];

The image looks good, but all the frame ticks are all gone. When you do

Export["xx.png", plot, ImageResolution -> 100];

The ticks are there, but the resolution of the image is not good enough.

I tried the trick of using ImportString and ExportString:

ImportString[ExportString[plot, "PDF"]

It works, but creates another problem: the PlotRangeClipping option is missing, and the figure has plot lines sticking out all the way to the boundary of the image, not the boundary of the axes.

Can someone provide an easy and relatively universal workaround?

Answer 1

The following workaround can be seen as an alternative to simpler and more reliable (but in some situations not appropriate) workaround suggested by Jens. It is not perfect because in addition to being significantly more complicated it has several limitations due to abundance of bugs in Export-related functionality:

• ImageSize must be specified in Export explicitly, it is not sufficient to provide it inside of Graphics expression

• Scaled font size specification for tick mark labels must be provided via the FrameTicksStyle option in order to the default ImagePadding -> All behaving properly

• The font size of PlotLabel must be absolute because specifying it as Scaled reveals a bug

• I'm sure there also are other situations when handling of Scaled font size is broken and absolute font size must be specified

• The distance between the tick mark labels and the frame gets smaller when you increase ImageSize and there is no proper way to control this distance

The following is a way to generate scalable tick marks and tick mark labels for all types of plots using only built-in (but undocumented) functions of version 10. Please note that it works correctly only for version 10 and already includes a fix for this bug (tested with versions 10.2 and 10.3.1):

data = Array[# &, 600];

linearFrameTicks = {
   {Most /@ Charting`ScaledTicks[{Identity, Identity}][##] &, 
    Most /@ Charting`ScaledFrameTicks[{Identity, Identity}][##] &}, 
   {Most /@ Charting`ScaledTicks[{Identity, Identity}][##] &, 
    Most /@ Charting`ScaledFrameTicks[{Identity, Identity}][##] &}};
p1 = Show[ListPlot[data, Frame -> True, FrameStyle -> Thickness[.003], 
    FrameTicksStyle -> Directive[FontSize -> Scaled[.02], Thickness[.003]]], 
   FrameTicks -> linearFrameTicks, PlotLabel -> "Linear FrameTicks", 
   LabelStyle -> FontSize -> 40, ImageSize -> 1000];
Export["p1.png", p1, ImageSize -> 1000]

linearLogFrameTicks = {
   {Most /@ Charting`ScaledTicks[{Log, Exp}][##] &, 
    Most /@ Charting`ScaledFrameTicks[{Log, Exp}][##] &}, 
   {Most /@ Charting`ScaledTicks[{Identity, Identity}][##] &, 
    Most /@ Charting`ScaledFrameTicks[{Identity, Identity}][##] &}};
p2 = Show[ListLogPlot[data, Frame -> True, FrameStyle -> Thickness[.003], 
    FrameTicksStyle -> Directive[FontSize -> Scaled[.02], Thickness[.003]]], 
   FrameTicks -> linearLogFrameTicks, PlotLabel -> "LinearLog FrameTicks", 
   LabelStyle -> FontSize -> 40, ImageSize -> 1000];
Export["p2.png", p2, ImageSize -> 1000]

logLinearFrameTicks = {
   {Most /@ Charting`ScaledTicks[{Identity, Identity}][##] &, 
    Most /@ Charting`ScaledFrameTicks[{Identity, Identity}][##] &}, 
   {Most /@ Charting`ScaledTicks[{Log, Exp}][##] &, 
    Most /@ Charting`ScaledFrameTicks[{Log, Exp}][##] &}};
p3 = Show[ListLogLinearPlot[data, Frame -> True, FrameStyle -> Thickness[.003], 
    FrameTicksStyle -> Directive[FontSize -> Scaled[.02], Thickness[.003]]], 
   FrameTicks -> logLinearFrameTicks, PlotLabel -> "LogLinear FrameTicks", 
   LabelStyle -> FontSize -> 40, ImageSize -> 1000];
Export["p3.png", p3, ImageSize -> 1000]

logLogFrameTicks = {
   {Most /@ Charting`ScaledTicks[{Log, Exp}][##] &, 
    Most /@ Charting`ScaledFrameTicks[{Log, Exp}][##] &}, 
   {Most /@ Charting`ScaledTicks[{Log, Exp}][##] &, 
    Most /@ Charting`ScaledFrameTicks[{Log, Exp}][##] &}};
p4 = Show[ListLogLogPlot[data, Frame -> True, FrameStyle -> Thickness[.003], 
    FrameTicksStyle -> Directive[FontSize -> Scaled[.02], Thickness[.003]]], 
   FrameTicks -> logLogFrameTicks, PlotLabel -> "LogLog FrameTicks", 
   LabelStyle -> FontSize -> 40, ImageSize -> 1000];
Export["p4.png", p4, ImageSize -> 1000]

Answer 2

OK, I'll just put up this work-around - it's not perfect because the scaling of the ticks has never worked properly, to my knowledge:

list = {{{10., 5.}, {40., 20.}, {160., 80.}}, {{10., 1.83772}, {40., 
     13.6754}, {160., 67.3509}}, {{10., 8.16228}, {40., 
     26.3246}, {160., 92.6491}}};

myPlot = ListPlot[list, Frame -> True, 
   FrameLabel -> {"Sample Size n", "Number of Successes: k "}, 
   FrameTicksStyle -> Directive[Large, FontSize -> 12], 
   ImageSize -> 6*72];

Export["plot.png", Style[myPlot, Magnification -> 1], 
 ImageResolution -> 360, ImageSize -> 6*72]

This doesn't display very well at the small ImageSize that was specified in the question, so I tripled that size. You can adjust the Magnification to vary the relative size of the ticks. For this image size, a value of 1 seems to work best. It's counter-intuitive, but you have to include the Style command even though it seems to do nothing.

For a smaller image size, you should choose a larger value, e.g., Magnification -> 2 to get the ticks to be visible.

Answer 3

It is doof but it is working (I had the same problem):

Export["p5.png", 
 Import[Export["p5.pdf", p5, ImageSize -> 360, 
   ImageResolution -> 1000]], ImageResolution -> 1000]

where p5 the name of your plot

Answer 4

UPDATE

Starting from Mathematica version 9 one can use comparatively simple workaround suggested by Jens. For previous versions the only known workaround is providing manual Ticks specifications, see below.

---

Original answer

This problem is described here as well.

Slava Nadvorny suggests using manual Ticks specifications. In this case they will scale with ImageResolution.

The CustomTicks package will make it considerably easier to create manual tick specifications.

Answer 5

I finally create a rasterized eps file with sufficent quality for my needs without losing the ticks. Maybe can be helpful even for other file formats outputs.

Try this double rasterization, where you can increase the ImageResolution value, but I do not recomend to increase the RasterSize beyond 515 or the ticks will disappear:

myPlot

Rasterize[%, "Graphics", RasterSize -> 500];

Rasterize[%, "Graphics", ImageResolution -> 350]

Export["myPlot.eps", %]