Bug introduced in 8 or earlier and persisting through 12.0

I'm trying to plot a graph wit a logarithmic y-axis. Since I'm exporting the graph to pdf and later printing it, I want to manually set the frame and tick marks to a reasonable thickness. However the logarithmic tick marks do not change their thickness.

(Note: I exaggerated the thickness of the tick marks on purpose to illustrate my point.)

LogPlot[x^2, {x, 1, 3}, PlotStyle -> Red, Frame -> True,
FrameStyle -> Directive[Black, AbsoluteThickness[2]],
FrameTicksStyle -> Directive[Black, AbsoluteThickness[2]]

Plot with Logarithmic Ticks

I'm working with Mathematica 10 on Mac OS X 10.9.4. In Mathematica Version 9 the logarithmic tick marks change their thickness as expected.

Can anyone reproduce this behavior? Is this a bug or did the FrameTicksStyle change in Mathematica 10?

  • 1
    $\begingroup$ I get the same (same system). $\endgroup$
    – Michael E2
    Commented Aug 15, 2014 at 10:52
  • $\begingroup$ Same here, v11.0.1.0, Linux Mint 18 64 bits. $\endgroup$
    – a06e
    Commented Jan 23, 2017 at 14:54
  • 1
    $\begingroup$ A duplicate question which contains better fix: "How do I adjust the thickness of all the FrameTicks?" $\endgroup$ Commented Sep 9, 2017 at 5:44

2 Answers 2


Reproduced in v.10.0.0 under Win7 x64. In versions 8.0.4 and 9.0.1 the behavior differs in details but the bug is also present: only major logarithmic frame ticks change their thickness, but not minor ticks.

Let us elaborate. First of all, in v.10 the logarithmic tick specifications are generated dynamically when the plot is rendered by the FrontEnd by calling Charting`ScaledTicks and Charting`ScaledFrameTicks:

LogPlot[x^2, {x, 1, 3}, Frame -> True];
Options[%, FrameTicks]    
{FrameTicks -> {{Charting`ScaledTicks[{Log, Exp}], 
    Charting`ScaledFrameTicks[{Log, Exp}]}, {Automatic, Automatic}}}

Here is what these functions return (I have shortened the output for readability):

Charting`ScaledTicks[{Log, Exp}][1, 10]
{{2.30259, 10, {0.01, 0.}, {AbsoluteThickness[0.1]}}, 
{4.60517, 100, {0.01, 0.}, {AbsoluteThickness[0.1]}}, 
{6.90776, 1000, {0.01, 0.}, {AbsoluteThickness[0.1]}}, 
{9.21034, Superscript[10,4], {0.01, 0.}, {AbsoluteThickness[0.1]}}, 
{0., Spacer[{0, 0}], {0.005, 0.}, {AbsoluteThickness[0.1]}}, 
{0.693147, Spacer[{0, 0}], {0.005, 0.}, {AbsoluteThickness[0.1]}}}

It is clear that the thickness specifications are already included and have higher priorities than the FrameTicksStyle directive. That is the reason why the latter has no effect.

So this behavior reflects inconsistent implementation of Charting`ScaledTicks and Charting`ScaledFrameTicks which should NOT include styling into the tick specifications they generate. It is a bug.

Here is a function fixLogPlot which fixes this:

fixLogPlot[gr_] := 
  Show[gr, FrameTicks -> {{# /. _AbsoluteThickness :> (## &[]) &@*
         Exp}], # /. _AbsoluteThickness :> (## &[]) &@*
       Charting`ScaledFrameTicks[{Log, Exp}]}, {Automatic, 

 LogPlot[x^2, {x, 1, 3}, Frame -> True, 
  FrameTicksStyle -> Directive[Black, AbsoluteThickness[2]]]



Here is universal fix for version 10 which works for all types of log plots:

fixLogPlots[gr_] := 
 gr /. f : (Charting`ScaledTicks | Charting`ScaledFrameTicks)[{Log, Exp}] :>
                                                   (Part[#, ;; , ;; 3] &@*f)


And here is universal fix for versions 8 and 9:

fixLogPlots[gr_] := gr /. f : (Ticks | FrameTicks -> _) :> (f /. _Thickness :> (## &[]))
  • $\begingroup$ Great elaboration of the problem. (In my personal opinion this is a clearly bug.) I'm wondering if there is a way to overcome the problem and change the thickness of the logarithmic tick without having to manually override the ticks with my one values. $\endgroup$
    – theDriver
    Commented Aug 15, 2014 at 11:45
  • 1
    $\begingroup$ Added a workaround. $\endgroup$ Commented Aug 15, 2014 at 13:16
  • $\begingroup$ @AlexeyPopkov Well, not entirely. It fixes ListLogLogPlot and LogLogPlot, but one cannot then do Show and combine them. $\endgroup$
    – Carl
    Commented Apr 2, 2017 at 6:15
  • $\begingroup$ @Carl Can you give an example? It works for me. $\endgroup$ Commented Apr 2, 2017 at 6:26
  • $\begingroup$ @AlexeyPopkov There is a lot of code, and, I do not own the data. Suggestions as to what to show, and how to show it, would be helpful. $\endgroup$
    – Carl
    Commented Apr 2, 2017 at 7:09

This seems to be fixed in 12.1.1:

screenshot of notebook


Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.