How to plot spherical coordinates with a single $\theta$ for any $r$?

Question

I'm trying to plot this equation (I believe it to be a cone) in spherical coordinates: $$\theta = \pi/4$$ where $\theta$ is the zenith angle, as per the Mathematica convention, and $r$ takes on all positive real numbers.

Mathematica seems to require me to specify the $r$ values, and specify a range for $\theta$. The closest I've gotten is:

SphericalPlot3D[{R, -1, 1},{\[Theta],\[Pi]/4 - 0.1,\[Pi]/4 + 0.1}, {\[Phi], 0, 2 \[Pi]}]

which produces rings:

The question Plot a cone in spherical co-ordinates is related, but doesn't answer my question, because my goal is to continue using spherical coordinates as I plot more complicated equations.

My ultimate goal is to plot: $$ \cos 2 \phi = \cot^2 \theta$$ with $r$ taking on all positive real values.

How can I plot the above in spherical coordinates?

Answer 1

$Version

(* "14.1.0 for Mac OS X ARM (64-bit) (July 16, 2024)" *)

Clear["Global`*"]

conv = Thread[{r, theta, phi} -> ToSphericalCoordinates[{x, y, z}]]

(* {r -> Sqrt[x^2 + y^2 + z^2], theta -> ArcTan[z, Sqrt[x^2 + y^2]], 
 phi -> ArcTan[x, y]} *)

max = 5;

ContourPlot3D[
  Evaluate[Cos[2 phi] == Cot[theta]^2 /. conv],
  {x, -max, max}, {y, -max, max}, {z, -max, max},
  AxesLabel -> (Style[#, 14] & /@ {"x", "y", "z"})] // Quiet

Answer 2

Edit

Before I post this answer, I have test ContourPlot3D, but the lighting not so right. I finally found that we need to set NormalsFunction -> None.

Clear["Global`*"];
eqn = Cos[2 φ] == Cot[θ]^2;
ContourPlot3D[eqn, {r, 0, 10}, {θ, 0, π}, {φ, 0, 
  2 π}, 
 DisplayFunction -> 
  ReplaceAll[{r_Real, θ_Real, φ_Real} :> 
    Evaluate@FromSphericalCoordinates[{r, θ, φ}]], 
 PlotRange -> All, BoxRatios -> Automatic, Boxed -> False, 
 NormalsFunction -> None]

Clear[eqns];
eqns = {θ == π/4, φ == π/4, r == 4};
ContourPlot3D[eqns, {r, 0, 10}, {θ, 0, π}, {φ, 0,
   2 π}, 
 DisplayFunction -> 
  ReplaceAll[{r_Real, θ_Real, φ_Real} :> 
    Evaluate@FromSphericalCoordinates[{r, θ, φ}]], 
 PlotRange -> All, BoxRatios -> Automatic, Boxed -> False, 
 NormalsFunction -> None, PlotPoints -> 60, MaxRecursion -> 4]

Original

• It seems similar to https://mathematica.stackexchange.com/a/300018/72111.

Clear["Global`*"];
eqn = θ == π/4;
reg = DiscretizeRegion[
   ImplicitRegion[
    eqn, {{r, 0, 10}, {θ, 0, π}, {φ, 0, 
      2 π}}], {{-10, 10}, {-10, 10}, {-10, 10}}, 
   MaxCellMeasure -> .01, AccuracyGoal -> 3];
RegionPlot3D[reg, 
 DisplayFunction -> 
  ReplaceAll[{r_Real, θ_Real, φ_Real} :> 
    Evaluate@FromSphericalCoordinates[{r, θ, φ}]], 
 PlotRange -> All, BoxRatios -> Automatic, PlotPoints -> 80, 
 MaxRecursion -> 2,Boxed -> False]

• the result about eqn = φ == π/4.

• the result about eqn = r == 1.

• combine the three coordinates.{θ == π/4, φ == π/4, r == 1}