How do I make my discrete plot thicker?

Question

I am making a discrete plot and a regular function plot together. But my curve is so thick that for color-blind people, it's pretty much impossible to see the black dots of my discrete plot:

plot1 = ParametricPlot[{Sin[t], Cos[ t]}, {t, 0, 2 Pi}, 
   PlotStyle -> {Red, Thickness[0.01]}];

plot2 = ListPlot[Table[{Sin[n], Cos[n]}, {n, 50}], 
   PlotRange -> {-1, 1}];

Show[plot1, plot2]

I tried adding "thickness" parameter, but it didn't work.

Answer 1

I recommend using Graphics primitives for this kind of application, which gives you direct (and usually easier) control of appearance. As a bonus performance is usually better as well.

For simple applications such as this, if you don't also need the plots separately, you can use Epilog in ParametricPlot to insert these primitives:

ParametricPlot[{Sin[t], Cos[t]}, {t, 0, 2 Pi}, 
  PlotStyle -> {Red, Thickness[0.01]}, 
  Epilog -> {PointSize[Large], Point@Table[{Sin[n], Cos[n]}, {n, 50}]}
]

See documentation for PointSize and AbsolutePointSize for complete control of point size.

If you need the plots separately you can do that too, like this:

p1 = ParametricPlot[{Sin[t], Cos[t]}, {t, 0, 2 Pi}, 
       PlotStyle -> {Red, Thickness[0.01]}
     ];

p2 = Graphics[
       {PointSize[Large], Point @ Table[{Sin[n], Cos[n]}, {n, 50}]},
       PlotRange -> {-1, 1}
     ];

Show[p1, p2]

---

In a comment J. M. reminds us that this form for p2 also works:

p2 = ListPlot[Table[{Sin[n], Cos[n]}, {n, 50}], PlotStyle -> {Black, PointSize[Large]}];

My recommendation to use graphics primitives is so that more complicated styles are within reach and so that code may be shared between Graphics and Epilog. Perhaps I am complicating things for such a simple operation and you would prefer that.

Answer 2

Clear["Global`*"]
ParametricPlot[{Sin[t], Cos[t]}
 , {t, 0, 2 Pi}
 , PlotStyle -> Directive @@ {Red, AbsoluteThickness[6]}
 , Epilog -> {AbsolutePointSize[4], Yellow
   , Point@CirclePoints[50]}
 ]

---

---

1. I will interpret the {n, 50} as equally spaced points around the circle for which CirclePoints is custom designed.

2. Contrasting colors are perceived more easily.

3. Using Epilog and Absolute* directives adjust the appearance precisely as suggested in comments.

Answer 3

Using Haloing (new in 13.3)

GraphicsGrid[{
  ParametricPlot[{Sin[t], Cos[t]}, {t, 0, 2 Pi},
     Mesh -> {Range[0, 2 Pi, Pi/#]},
     MeshStyle -> Directive[Red, PointSize[Large]],
     PlotLabel -> "2 Pi/" <> ToString[#],
     PlotStyle -> Haloing[Yellow, 0, 4]] & /@ {12, 4, 2}}]