How to plot the mean of a 2d list with some empty elements

Question

How can I plot the mean of such a list: http://pastebin.com/dNjeR4WC which contains an alternating number of elements in the sublists and some sublists that are empty and should not be considered in the plot (the corresponding mean does not exist).

Example:

{{},{},{},{1,2},{1,2,3},{4,5},{3,4,5,6,7},{},{2,3,4,5,6},{6}}

For the upper example I would like to plot:

{{},{},{},Mean[{1,2}],Mean[{1,2,3}],Mean[{4,5}],Mean[{3,4,5,6,7}],{},
Mean[{2,3,4,5,6}],Mean[{6}]}

Answer 1

list = {{}, {}, {}, {1, 2}, {1, 2, 3}, {4, 5}, {3, 4, 5, 6, 
    7}, {}, {2, 3, 4, 5, 6}, {6}};
list // MapIndexed[If[#1 != {}, {First@#2, Mean@#1}] &] // 
  DeleteCases[Null] // ListPlot

Here it is with the larger data set

<< "http://pastebin.com/raw/dNjeR4WC" // 
   MapIndexed[If[#1 != {}, {First@#2, Mean@#1}] &] // 
  DeleteCases[Null] // ListPlot

Or, with a slightly shorter syntax (thanks to J.M. for pointing it out)

<< "http://pastebin.com/raw/dNjeR4WC" // Map[Mean] // 
  ReplaceAll[_Mean :> Missing] // ListPlot

both of which give the same result:

Answer 2

Example

data = {{}, {}, {}, {1, 2}, {1, 2, 3}, {4, 5}, {3, 4, 5, 6, 7}, {}, {2, 3, 4, 5, 6}, {6}}
Mean /@ Select[data, UnsameQ[#, {}] &]

Alternativly, here is a version proposed by @JasonB

data // Select[Not@*EqualTo[{}]] // Map[Mean]

Output

{3/2, 2, 9/2, 5, 4, 6}