Referencing previous elements in the same List

Question

I'm looking for a way to reference an element within a List to get another element in the same parent List. I can't really see any way to do this without either being able to specify a level that is above that element in a getter function or without some kind of self-referencing construct like .this() for object-oriented ADTs.

As a minimal example, is there a way to get

listex={MemoryInUse[],f[x],MemoryInUse[],difference}

where difference=listex[[3]]-listex[[1]], or is my sole option to generate a List without these dependent elements and then Insert/Append them post-creation?

Answer 1

Perhaps this:

{a = 1, b = 2, c = 3, a + b + c}

(* gives {1,2,3,6} *)

So you're assigning elements of a list to a variable, and then you can use them 'later' in the list.

Answer 2

listex = ReleaseHold /@ (listex = {MemoryInUse[], f[x], MemoryInUse[],
      Hold[#[[3]] - #[[1]] &@listex]})

$\ ${28548600, f[x], 28548688, 88}

Or

listex = Evaluate /@ (listex = {MemoryInUse[], f[x], MemoryInUse[], 
     Unevaluated[#[[3]] - #[[1]] &@listex]})

---

Real self-referencing may lead to an unexpected output:

listex = {MemoryInUse[], f[x], MemoryInUse[], #0[[1, 3]] - #0[[1, 1]]} &@Nothing

$\ ${44107848, f[x], 44107936, -72}

To understand what's going on use

listex = {Echo[MemoryInUse[], "1"], f[x], Echo[MemoryInUse[], "2"], 
    Echo[#0[[1, 3]], "3"] - Echo[#0[[1, 1]], "4"]} &@x

and check this answer.

Answer 3

It might be worthwhile to consider a construction like this:

{##, #3 - #1}&[MemoryInUse[], f[x], MemoryInUse[]]

While this does not meet the question's requirement to avoid list post-creation, there may still be some value due to the syntactic compactness.

Answer 4

Regular List can not contain references to itself. You can use the internal function Bag instead

AppendTo[$ContextPath, "Internal`"];

ClearAll[a];
a = Bag[{Random[], Random[], BagPart[a, 2] - BagPart[a, 1]}];

BagPart[a, 2] - BagPart[a, 1]
(* 0.65051 *)

BagPart[a, 3]
(* 0.65051 *)

BagPart[a, 1] = 0;
BagPart[a, 3]
(* 0.794121 *)

See also this answer.

Answer 5

This is a variant of Karsten's answer, using ReplaceAll:

listex = (listex = {MemoryInUse[], f[x], MemoryInUse[], 
 difference}) /. {difference -> (listex[[3]] - listex[[1]])}

{2083331656, f[x], 2083331744, 88}