Why is ListLogPlot skipping entire decades?

Question

I'm having an issue with Mathematica wherein, when trying to use ListLogPlot, the scale of the y-axis skips entire decades. Instead of 1, 10, 100, 1000, it goes more like 10^2,10^4,10^6,10^8. I need it to, well, not do this.

This is more or less my code, with different numbers introduced (although same order of magnitude)

data1 = {{{1, 1.432*10^8}, {2, 4.2*10^7}, {5., 1.68*10^7}, {7., 
   5.21*10^6}, {10., 1.02*10^6}, {12., 5.37*10^5.}, {15., 1.76*10^5.}, {17., 
   1.40*10^5.}, {20., 7.87*10^4}}}

Then

ListLogPlot[data1, Joined -> True, PlotMarkers -> {Automatic, Tiny}, 
 PlotStyle -> Red, PlotRange -> {{0, 20}, {1, 1000000000}}, 
 AspectRatio -> 1, Frame -> True]

And, at least for mine, it produces a graph wherein the ticks on the vertical log axis skip decades.

There should also be a large white blank space towards the bottom of the graph. This is intentional, as I have several other sets of data I need to include using the Show function, and Show seems to default to the first graph set. So if I can get this graph to work, then it should be pretty easy to graph the others, and use the Show function.

Any help is greatly appreciated.

Answer 1

you need to manually specify FrameTicks to override the default.

 ListLogPlot[data1, Joined -> True, PlotMarkers -> {Automatic, Tiny}, 
    PlotStyle -> Red, PlotRange -> {{0, 20}, {1, 1000000000}}, 
    AspectRatio -> 1, Frame -> True, 
    FrameTicks -> {Automatic, 
        Table[{10^i, Superscript[10, i] }, {i, 0, 10}], None, None}]

adding the sub ticks..

 ListLogPlot[data1, Joined -> True, PlotMarkers -> {Automatic, Tiny}, 
    PlotStyle -> Red, PlotRange -> {{0, 20}, {1, 1000000000}}, 
     AspectRatio -> 1, Frame -> True, FrameTicks -> {Automatic,
      Table[{10^i,
         Superscript[10, i], {.02, 0}}, {i, 0, 10}]~Join~
          Flatten[ Table[{j 10^i, , {.005, 0}}, {i, 0, 10}, {j, 2, 9 }], 1],
              None, None}]