What is better coding for turning list into sequence without curly brackets?

Question

There are less satisfying Q/A for what I am asking but none that actually answer the question. Suppose one has

a=1; b={2,3};

And one wants to print a sequence of numbers a, b, c without curly brackets. Then if one prints

Print[a,", ",b]

One obtains

1, {2,3}

One solution to this is to print

Print[a,", ",b[[1]],", ",b[[2]]]

Then one obtains

1, 2, 3

What is going on is that the only way to get rid of the curly brackets in a list is to extract single values from that list. So that single value extraction by parts is a solution to my question but not an efficient one for a longer list like

 b={2,3,4,5,6,7,8,9,10,11,12,13,14} 

So now the question. Is their a more efficient way to print a longer list without the curly brackets?

Answer 1

^{Converting a comment into an answer}

One way would be

Print @@ Riffle[Prepend[b, a], ", "]

For example,

a = 1;
b = {2, 3};
Print @@ Riffle[Prepend[b, a], ", "]

1, 2, 3

Answer 2

Converting comment into answer as suggested:

a = 1; b = {2, 3};
Print[a, ", ", Sequence @@ Riffle[b, ", "]]

(* Out: 1, 2, 3 *) 

Answer 3

Also

Row[Flatten @ {a, b}, ","]

Answer 4

In this case you are printing the InputForm of whatever expression you give to Print. So if you want to print the String "1, 2, 3" then you will need to construct that String to print.

The following does what you need (and works for any number of Lists of elements):

a = {1};
b = {2, 3};

str = StringRiffle[Join[a, b], ", "]

Yields

1, 2, 3

And if you want to Print this (which may not be the right tool in the first place depending on what you want to do), then you can just Print[ str ] and it will do what you want.

The idea is to join the lists together and then separate them by commas as a String.

Hope this helps!