Defining a function that prints both the name and value of a variable defined locally within the calling function

Question

To save time when debugging with Print statements, I'd like to define a function -- call it PrintVal -- that prints both the name and value of a variable defined locally within the calling function. The function would be called with a single argument, which would be the name of the variable in question (expressed in the form of a string). To provide a concrete example, if fooVar is a variable defined as local to a module within the calling function, and if the current value of fooVar is 9, then

PrintVal[ "fooVar" ]

should print

fooVar = 9

The new function would thus have the same effect as including the statement

Print[ "fooVar = ", fooVar ]

directly within the calling function itself, but without the need to type the variable name twice, to include the equal sign, and (most important from a time-saving perspective) to include some other formatting stuff that I haven't mentioned here (because it's not relevant to the part I'm struggling with).

Although there may well be an embarrassingly simple solution that I don't know enough to have thought of, after a considerable amount of experimentation, documentation-reading, and web-searching, I've been unable to find one. With apologies in advance if I'm missing something obvious, I'd be very grateful to anyone who might provide a (detailed and concrete) solution.

Many thanks!

Answer 1

Here is a method that is not exactly to your specification but which may serve you anyway. It uses a Symbol argument. Because a Symbol is passed it is automatically modified by Module and does not need the guesswork of $ModuleNumber etc. but it does need string conversion and cleanup.

SetAttributes[printVal, HoldFirst];

printVal[s_Symbol] := 
  Print @ Row[{StringTrim[SymbolName@Unevaluated@s, "$" ~~ DigitCharacter ..], s}, "="]

An example:

b = "Fail!" (*this should not print!*);

Module[{b},
 b = RandomInteger[9, 3]^2;
 printVal[b];
 b
]

b = {16, 4, 36}

{16, 4, 36}

---

Regarding why naive attempts fail you must consider the mechanism of Module; only visible (explicit) Symbols in the body are substituted by localized equivalents. A String that is later converted to a Symbol is not included in this localization:

b = "Fail!";

Module[{b},
 b = RandomInteger[9, 3]^2;
 Print[b];
 Print[Unevaluated@b];
 Print[Symbol["b"]];
]

{81, 64, 36}

b$2061

Fail!

Note that Symbol["b"] evaluates to the global b rather than the localized b$2061.