Plotting best-response functions

Question

I'm a newbie in Mathematica. I'm trying to solve for two functions (best-response functions in a simple game), and then to plot the functions on the same graph. One function is p1 = resp1(p2) and the other is p2 = resp2(p1). I'd like to plot them both such that p1 is the x-axis and p2 is on the y-axis. The goal is that I'd like to be able to alter the form of q1 and q2 and easily see how the shape of the best-responses functions change and how many equilibria exist (the intersections of the best responses).

q1 = A - a*p1 + c*CDF[GammaDistribution[α, β], p2];
q2 = B - b*p2 + c*CDF[GammaDistribution[α, β], p1];
r1 = (p1 - mc)*q1;
r2 = (p2 - mc)*q2;
BR1t = FullSimplify[Solve[ D[r1, p1] == 0, p1, Reals],Assumptions -> {p2 > 0, p1 > 0}];
BR2t = FullSimplify[Solve[ D[r2, p2] == 0, p2, Reals],Assumptions -> {p1 > 0, p2 > 0}];
A = 100; B = 100; a = 1;  b = 1; c = 30; mc = 1;
α= 4; β = 2; 
resp1 = p1 /. First[BR1t]
resp2 = p2 /. First[BR2t]

g1 = Plot[resp1, {p2, 1, 100}]
g2 = Plot[resp2, {p1, 1, 100}]

I'm not sure what comes next in terms of creating the single plot.... any help would be appreciated.

Thank you.

Answer 1

You can also use a single ParametricPlot with two datasets:

bresp1[x_] := 201/2 + 30 GammaRegularized[4, 0, x/2];
bresp2[x_] := 1/2 (101 + 30 GammaRegularized[4, 0, x/2]);
ParametricPlot[{{x, bresp1[x]}, {bresp2[x], x}}, {x, 0, 200}, 
PlotStyle -> {{Blue, Thick}, {Red, Thick}}, 
PlotRange -> {{0, 200}, {0, 200}}, AspectRatio -> 1]

EDIT: Manipulate with all model parameters:

br[A_?NumericQ, a_?NumericQ, \[Gamma]_?NumericQ, \[Alpha]_?NumericQ, \[Beta]_?  NumericQ, c_?NumericQ, x_?NumericQ] := 
( a c + A + \[Gamma] GammaRegularized[\[Alpha], 0, x/\[Beta]])/(2 a)
Manipulate[ ParametricPlot[{{x, br[A, a, \[Gamma], \[Alpha], \[Beta], c1, x]}, 
{br[B,  b, \[Gamma], \[Alpha], \[Beta], c2, x], x}}, {x, 0, 200}, 
PlotStyle -> {{Blue, Thick}, {Red, Thick}}, 
PlotRange -> {{0, 200}, {0, 200}}, AspectRatio -> 1], 
Style["Demand System Parameters", "Subsection"], 
{{A, 100, "A"}, 10, 200, 10}, {{a, .5, "a"}, .1, 2, .1}, 
{{B, 100, "B"}, 10, 200, 10}, {{b, .5, "b"}, .1, 2, .1}, Delimiter,
{{\[Gamma], -50, "\[Gamma]"}, -100, 100, 5}, Delimiter, 
{{\[Alpha], 6, "\[Alpha]"}, 1, 10, .1},
{{\[Beta], 6, "\[Beta]"}, 1, 10, .1}, Delimiter, 
Style["Cost Parameters", "Subsection"], 
{{c1, 5, "c1"}, 0, 15, .1}, {{c2, 5, "c2"}, 0, 15, .1}
ControlPlacement -> Left]

Answer 2

Basically, what you want to do is to swap the axes for one of the two plots. Usually the best way to do this is with ParametricPlot. Try this code to get a flavour of how it works:

plot1 = Plot[x^2, {x, 0, 2}, AspectRatio -> 1]
plot2 = ParametricPlot[{x^2, x}, {x, 0, 2}, AspectRatio -> 1]
Show[plot1, plot2]

With your example above, the code would be

nullPlot = Plot[Null, {x, 1, 100}, PlotRange -> {1, 100}, AspectRatio -> 1];
g1 = Plot[resp1, {p2, 1, 100}];
g2 = ParametricPlot[{resp2, p1}, {p1, 1, 100}];
Show[nullPlot, g1, g2]

the first line of which creates an empty set of axes with the relevant x,y ranges.

Also, if you want to see how your parameters affect the equilibrium you can use something like

Manipulate[
    plot1 = Plot[a*x^2, {x, 0, 2}, AspectRatio -> 1, PlotRange -> {0, 2}]; 
    plot2 = ParametricPlot[{a*x^2, x}, {x, 0, 2}, AspectRatio -> 1]; 
    Show[plot1, plot2], {a, 1, 2}]