Drawing a straight line perpendicular to the x-axis wih Plot

Question

I want to plot a straight line perpendicular to the $x$-axis at $x=1$. None of the following attempts work:

Plot[EvenQ[x == 1], {x, -1, 2}]
Plot[x == 1, {x, -1, 2}]
Plot[1, {x, -1, 2}]

I have only managed to do it with ContourPlot:

ContourPlot[Evaluate[x == 1], {x, -1, 2}, {y, -1, 2}, Axes -> True]

How can I use Plot command to draw a straight line perpendicular to the x-axis?

Answer 1

Using InfiniteLine: (2nd syntax variation)

If you application requires adding lines only, this should be okay.

Plot[Tanh[x], {x, -2, 2}
 , Epilog -> {
   Dashed, Red
   , InfiniteLine[{1, 0}, {0, 1}]
   }
 ]

---

Using ContourPlot:

Much more flexible, as any implicit equation can be plotted with the following method.

Show[
 Plot[Tanh[x], {x, -2, 2}]
 , ContourPlot[x == 1
  , {x, -2, 2}, {y, -2, 2}
  , ContourStyle -> {Dashed, Red}
  ]
 ]

---

Result:

Answer 2

May be Epilog?

Plot[x, {x, -1, 2}, Epilog -> Line[{{1, -1}, {1, 3}}]]

gives

You can change the style as needed. For example

Plot[x, {x, -1, 2}, Epilog -> {Dashed, Red, Line[{{1, -1}, {1, 3}}]}]

Answer 3

Try

Show[
  Plot[x^2+1/2,{x,-2,2}],
  ListPlot[{{1,0},{1,4}},Joined->True]
]

Answer 4

As mentioned in the comments:

Plot[x, {x, -1, 2}, GridLines -> {{1}, {}}, GridLinesStyle -> Directive[Red, Dashed]]