Drawing a pair of lines to the x-axis and y-axis from a point along a curve

Question

I have some plot like the following:

Plot[Cos[x], {x, -10, 10}, AxesLabel -> {Style["x-axis", 12], Style["y-axis", 12]}, ImageSize -> {650, 650}]

I'd like to be able to specify a point along the x-axis and draw a line of some color from this point to a point immediately above or below it falling along the given curve, and then draw a line from this point on the curve to a point immediately to the left or right of the point on the curve to a point on the y-axis (wherever either of these two axes are positioned). Is there a built-in way to do this in Mathematica 9?

The purpose of this is to make it obvious where a point p on the curve falls along the x-axis and y-axis in the plot.

Answer 1

Like this, Epilog?

With[{expr = Cos[x], x0 = 5.4}, 
 Plot[expr, {x, -10, 10}, 
  AxesLabel -> {Style["x-axis", 12], Style["y-axis", 12]}, 
  ImageSize -> {650, 650},
  Epilog -> {Lighter@Red, 
    Line[{{x0, 0}, {x0, expr /. x -> x0}, {0, expr /. x -> x0}}]}]
 ]

Or perhaps with GridLines?

With[{expr = Cos[x], x0 = 5.4}, 
 Plot[expr, {x, -10, 10}, 
  AxesLabel -> {Style["x-axis", 12], Style["y-axis", 12]}, 
  ImageSize -> {650, 650},
  GridLines -> {{x0}, {expr /. x -> x0}},
  GridLinesStyle -> Lighter@Red]
 ]