Colour coding a ListPlot from a 3rd string value

Question

I'm trying to format a csv file to give a plot with x and y coordinates, but colour coded by a third value that is a string. I have no issue reading the data in and can plot the x and y coordinates. But I am a little stuck on how to colour code the plot from the strings.

E.g. of the data [2.3, 3.4, phot, 4.1, 5.2, compt]

So far I've read the data in and plotted it. My code so far is: AlNP20 = Import["file.csv", {"Data", 1 ;; 271, {1, 2}}];

AlNPProcess20 = Import["file.csv", {"Data", 1 ;; 271, {11}}];

ListPlot[AlNP20]

This gives me the plot of x and y, but any help on how to incorporate the strings as colour coding would be greatly appreciated!

Answer 1

Let's say, you have your data with three tags (first, second and third). I made it manually:

d = Flatten[
  Table[{i, i^2 + RandomReal[30 i], j}, {i, 1, 
    50}, {j, {"f", "s", "t"}}]]

{1, 28.2759, "f", 1, 14.2023, "s", 1, 20.0824, "t", 2, 20.3635, "f",
2, 31.7858, "s", 2, 55.8098, "t",...}

Let's separate them by tags:

r = Table[#[[i ;; i + 2]], {i, 1, Length@# - 2, 3}] &@d;

c1 = Select[r, #[[3]] == "f" &][[All, {1, 2}]];
c2 = Select[r, #[[3]] == "s" &][[All, {1, 2}]];
c3 = Select[r, #[[3]] == "t" &][[All, {1, 2}]];

It gives three lists of data that are plotable by ListPlot:

ListPlot[{c1, c2, c3}, PlotStyle -> {Red, Green, Blue}, 
 Joined -> True, PlotLegends -> {"f", "s", "t"}]

Answer 2

You can use GroupBy

For example using the toy data from @Rom38 answer:

d = Flatten[
   Table[{i, i^2 + RandomReal[30 i], j}, {i, 1, 
     50}, {j, {"f", "s", "t"}}]];

You could do:

dt = Partition[d, 3];
ListPlot[GroupBy[dt, #[[3]] &, #[[All, {1, 2}]] &], Joined -> True]