These don't have solutions over the complexes?

Question

I've tried W. Alpha for solving the equation involving the Lambert W function , but it seemed that W.A is either couldn't understand the expressions or it just simply doesn't have solutions over the complexes . The equations are :

• $W(- \log x ) / (-\log x) = e$
• $W(-\log x) / (-\log x) = \pi$
• $W(-\log x) / (-\log x) = i$

Do these have no solutions over the complexes ? (thanks).

Answer 1

For the first equation, NSolve can produce a solution if you include a domain restriction:

NSolve[ProductLog[-Log[x]]/-Log[x]==E&&-10<x<10, x]

{{x -> 1.44467}}

For the second equation, I don't think there is a solution using the principal solution (of the ProductLog function):

NSolve[ProductLog[-Log[x]]/-Log[x]==Pi&&Abs[x]<10, x]

{}

If you use a different solution of the ProductLog function, both Solve (and NSolve) can find a solution:

NSolve[ProductLog[1, -Log[x]]/-Log[x]==Pi&&Abs[x]<10, x]

{{x -> -0.599093 - 1.30904 I}}

For the third equation, both Solve and NSolve are unable to find a solution. Instead, you can try FindRoot:

FindRoot[ProductLog[-Log[x]]/-Log[x]-I, {x, 4+I}]

{x -> 4.81048 + 9.58707*10^-6 I}

However, it's not clear to me whether the above is actually a root, since the accuracy of the result after substitution doesn't increase when working precision is increased.

Answer 2

You can get analytical solutions with Reduce, if you use the definition equation for ProductLog z = w*E^w.

Here calculated for all three equations together with tests.

   Reduce[z == w E^w, w]
(*                                        *)                     
red1 = Reduce[{w/z == E, z + Log[x] == 0, z == w E^w}, x]

rule1 = (Rule @@ First@Cases[#, x == xsol__] &) /@ red1

ProductLog[0, -Log[x]]/-Log[x] - E /. rule1[[1]] // N

ProductLog[-1, -Log[x]]/-Log[x] - E /. rule1[[2]] // N

ProductLog[1, -Log[x]]/-Log[x] - E /. rule1[[3]] // N

(*                                          *)
red2 = Reduce[{w/z == Pi, z + Log[x] == 0, z == w E^w}, x]

rule2 = (Rule @@ First@Cases[#, x == xsol__] &) /@ red2

ProductLog[-1, -Log[x]]/-Log[x] - Pi /. rule2[[1]] // N

ProductLog[1, -Log[x]]/-Log[x] - Pi /. rule2[[2]] // N

ProductLog[-1, -Log[x]]/-Log[x] - Pi /. rule2[[3]] // N

(*                                                 *)
red3 = Reduce[{w/z == I, z + Log[x] == 0, z == w E^w}, x]

rule3 = Rule @@ First@Cases[red3 /. C[1] -> c1, x == xsol__]

Table[ProductLog[c1, -Log[x]]/-Log[x] - I /. rule3, {c1, 1, 5}] // 
N // Chop

ProductLog[-1, -Log[x]]/-Log[x] - I /. rule3 /. c1 -> 0 // N

Solutions for the three equations

 (x -> E^(1/E)) || (x -> E^((I (2 \[Pi] - I))/E)) || (x -> 
 E^(-((I (2 \[Pi] + I))/E)))

(x -> E^((I (2 \[Pi] - I Log[\[Pi]]))/\[Pi])) || (x -> 
E^(-((I (2 \[Pi] + I Log[\[Pi]]))/\[Pi]))) || (x ->    \[Pi]^(1/\[Pi])
 )

x -> E^(-(1/2) (-1 + 4 c1) E^(2 I c1 \[Pi]) \[Pi])