1
$\begingroup$

I am trying to solve the equation system eq1==eq2 for $\sigma1$ and $\sigma2$ where eq1 and eq2 are functions of 5 positive real variables as defined below:

eq1=(2 Sqrt[5 + 4 x1 + x1^2 + 2 y1 + y1^2])/(Sqrt[5] (2 + x1) (1 +y1))

eq2= (2 (1 + s) Sqrt[5 + 5 s^2 + 4 x1 σ1 + x1^2 σ1^2 + 2 y1 σ2 + y1^2 σ2^2 + 2 s (5 + 2 x1 σ1 + y1 σ2)])/(Sqrt[5] (2 + 2 s + x1 σ1) (1 + s + y1 σ2))

I am interested only in those solutions which are only a function of variable s. As a matter of fact I can simply verify that s+1 is a solution:

eq2 /. {σ1 -> 1 + s, σ2 -> 1 + s} //FullSimplify[#, s > 0] &

however, I have not been able to find this solution using Mathematica.

I have tried the following

Reduce[eq1 == eq2 && 0 < x1 && 0 < y1 && 0 < σ1 &&0 < σ2 && 0 < s, {σ1, σ2},Reals] // FullSimplify

and

Solve[eq1 == eq2, {σ1, σ2}, Reals] // FullSimplify

but none of these result in the simple solution s+1. My question is what is the right approach to solving this kind of equations in Mathematica.

$\endgroup$

1 Answer 1

3
$\begingroup$

SolveAlways might be the way to go. You are after relations between $\sigma1$, $\sigma2$ and $s$ which make the equation hold for all values of $x1$ and $y1$, so you would use:

SolveAlways[eq2 == eq1, {x1, y1}]

Unfortunately this seems very slow and I wasn't patient enough to let it finish. However, squaring both sides gives results quickly:

SolveAlways[eq2^2 == eq1^2, {x1, y1}] // DeleteDuplicates

(* {{σ1 -> 0, s -> -1}, {σ1 -> 1 + s, σ2 -> 1 + s}, {σ2 -> 0, s -> -1}} *)
$\endgroup$
2
  • $\begingroup$ Many thanks @Simon Woods. I am still running the first line to see if I get a solution. $\endgroup$
    – user371
    Jun 5, 2014 at 10:01
  • $\begingroup$ You got any solution? $\endgroup$
    – LCarvalho
    Sep 24, 2016 at 1:22

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.