0
$\begingroup$

I am having issues solving rather simple equations with these functions.

enter image description here

The equations are

enter image description here

I have plotted each equation and its obvious that there are multiple solutions to these equations (excluding the second equation). However when I ask Mathematica to solve these equations it only gives me one solution. This is what I wrote:

FindInstance[f[x] == g[x], {x}]

FindInstance[g[x + 1]*f[x + 1] == h[x + 5], {x}]

I couldn't solve these with the Solve command because it yielded an error message. I have tried to solve these equations with the Reduce command but that only crashes my computer for some reason.

I wish to find the intervals where these equations are satisfied.

$\endgroup$
2
  • $\begingroup$ FindInstance has an optional argument that tells it how many answers to give. For example, FindInstance[f[x] == g[x], {x}, 4] gives 4 answers. Reduce[h[x + 10] == g[x], x] also gives tow answers. $\endgroup$
    – bill s
    Jul 22, 2023 at 19:39
  • 1
    $\begingroup$ Please add your functions and equations as Mathematica code (text) rather than screenshots. It's easier if we don't have to retype your equations in order to try and help $\endgroup$
    – MarcoB
    Jul 23, 2023 at 0:31

1 Answer 1

1
$\begingroup$
$Version

(* "13.3.0 for Mac OS X ARM (64-bit) (June 3, 2023)" *)

Clear["Global`*"]

f[x_] = x Cos[x];
g[x_] = (x^2 - 5)^(1/3);
h[x_] = Abs[x + 2];

sol1 = Solve[{f[x] == g[x], -10 < x < 10}, x, Reals] // N

(* {{x -> -8.35549}, {x -> -4.12371}, {x -> 5.28005}, {x -> 7.33239}} *)

Or

FindInstance[{f[x] == g[x], -10 < x < 10}, x, 4] // N

(* {{x -> -8.35549}, {x -> -4.12371}, {x -> 5.28005}, {x -> 7.33239}} *)

Plot[{f[x], g[x]}, {x, -9, 8},
 Frame -> True,
 Epilog -> {Red, AbsolutePointSize[5],
   Point[{x, f[x]} /. sol1]}]

enter image description here

sol2 = Solve[{g[x] == h[x + 10], -20 < x < 20}, x, Reals] // N

(* {{x -> -8.0792}, {x -> -19.1168}} *)

Or

FindInstance[{g[x] == h[x + 10], -20 < x < 20}, x, 2] // N

(* {{x -> -8.0792}, {x -> -19.1168}} *)

Plot[{g[x], h[x + 10]}, {x, -20, -5},
 Frame -> True,
 Epilog -> {Red, AbsolutePointSize[5],
   Point[{x, g[x]} /. sol2]}]

enter image description here

sol3 = Solve[{g[x + 1] f[x + 1] == h[x + 5], -10 < x < 10}, x, Reals] // N

(* {{x -> -8.91669}, {x -> -5.59041}, {x -> -3.71324}, {x -> 4.50462}, 
    {x -> 6.33311}} *)

Or

FindInstance[{g[x + 1] f[x + 1] == h[x + 5], -10 < x < 10}, x, 5] // N

(* {{x -> -5.59041}, {x -> -3.71324}, {x -> 4.50462}, {x -> 6.33311}, 
    {x -> -8.91669}} *)

Plot[{g[x + 1] f[x + 1], h[x + 5]}, {x, -10, 10},
 Frame -> True,
 Epilog -> {Red, AbsolutePointSize[5],
   Point[{x, h[x + 5]} /. sol3]}]

enter image description here

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.