Color labels in Listplot

Question

Bug introduced in 11.0 and fixed in 11.1

---

Given a ListPlot like this, for example:

data = RandomReal[{-1, 1}, {10, 2}];
labels = Flatten@RandomInteger[{1, 2}, {10, 1}]
ListPlot[data -> labels]

How can I style the labels with a specific color? It kind of freaks me out that it is not possible to just use Style on the labels variable like this:

data = RandomReal[{-1, 1}, {10, 2}];
labels = Style[Flatten@RandomInteger[{1, 2}, {10, 1}], Red]
ListPlot[data -> labels]

Then, no labels are shown at all.

Also, how can I increase the distance between points and corresponding labels?

I'm using mathematica: 11.0.1.0

Answer 1

This is a bug that's been fixed in the latest version. Compare this code in versions 11.0.1 and 11.1.1

data = RandomReal[{-1, 1}, {10, 2}];
labels = Map[Style[#, Red] &]@RandomInteger[{1, 2}, 10];
$VersionNumber
ListPlot[data -> labels]

Here is a workaround for this example

myStyle := Sequence[Red, Bold, FontFamily -> "Comic Sans MS"]
ListPlot[data -> labels] /. 
 Pane[Style[label_, {}]] :> Pane[Style[label, myStyle]]

Answer 2

Here is a bit of a monster but it works

If[
    #1 == 1, 
    Text[Style[#1, Red], #2 + {0, .05}],
    Text[Style[#1, Blue], #2 + {0, .05}]
    ] & @@@ MapThread[List, {labels, data}] // 
 Graphics[{
    #, Point @ data
    },
   Axes -> True
   ] &

This code is by no means clean nor efficient :). It only serves as a demonstration that it is possible to achieve the effect you are describing.

Answer 3

Try this:

data = RandomReal[{-1, 1}, {10, 2}];
labels = Map[Style[ToString[#], 12, Red, Bold] &, 
   Flatten@RandomInteger[{1, 2}, {10, 1}]];
ListPlot[data -> labels]

or this:

labels = Map[If[# == 1, Style[ToString[#], 12, Red, Bold], 
     Style[ToString[#], 12, Blue, Bold]] &,Flatten@RandomInteger[{1, 2}, {10, 1}]];
ListPlot[data -> labels]

Have fun!