How to create an effective PlotLegend when plotting many ListPlots?

Question

I'm creating a ListPlot where I plot many data sets simultaneously. Currently, my code that produces it is something like this:

ListPlot[alldat, PlotStyle -> "Rainbow", PlotLegends -> SwatchLegend["Rainbow", flist]]

Where alldat is my list of data sets, and flist is a list of their names (corresponding to alldat, so in the same order).

This produces this:

The important part I'm asking about is the legend, and the labeling colors. This graph only has 10 curves and already it's getting pretty hard for me to differentiate between some of them (I can do it but I have to squint and concentrate for a minute). I know that at some point I'm just going to crowd the plot so much it won't matter what color or pattern they are, but I'd like to go up to maybe 20 curves.

How can I plot them and label them clearly so I can tell them apart? Maybe only use 5 different colors, but 4 times of pattern or something (solid, dashed, dot dashed, dotted). I know I could list out all the things separately but I want something that will automatically work for a variable amount of curves.

Is there a clever way to do this?

Answer 1

If it is to be printed and you have space (say, a page), then a grid can be effective, where each dataset is plotted in a highlight color over a monochromatic plot of all datasets:

maxmin = {Min /@ Transpose[data], Max /@ Transpose[data]};
background = 
  ListLinePlot[Join[maxmin, data], PlotStyle -> Directive[Thin, Gray],
    Filling -> {1 -> {2}}];
plots = MapThread[
   ListPlot[#, PlotStyle -> #2, AbsoluteOptions[background, PlotRange],
     PlotLabel -> "Dataset " <> ToString[#3]] &,
   {data, ColorData[97] /@ Range[Length@data], Range[Length@data]}];

GraphicsGrid[
 Partition[
  Show[
     background,
     #,
     Options[#]
     ] & /@ plots,
  4],
 ImageSize -> Full]

In Mathematica, one can highlight each plot with something like TabView. You lose the ability to scan the relationships at a glance that I think you get with the grid view above, but the individual graphs can be inspected more easily.

TabView[Show[
    background,
    #,
    Options[#]
    ] & /@ plots]

Basically I am suggesting that it is hard to look at a plot of a dozen or twenty graphs and be able to easily discern important information as well as suggesting one alternative presentation.

Answer 2

Assuming you really want solid lines for your data, I'd suggest something like the following.

ListLinePlot[fakedata, 
 PlotStyle -> (Flatten@
    Outer[Directive, {AbsoluteThickness[1.5], Dashing[0.02], 
      DotDashed, Dotted}, Take[ColorData[22, "ColorList"], 5]])]

For shorter data series in the data set, PlotMarkers can help if you truncate your colour palette.

ListLinePlot[fakedata,  PlotStyle -> Take[ColorData[22, "ColorList"], 5], 
 PlotMarkers -> Automatic ]