Workarounds for a possible bug in the linearity of FourierTransform

Question

This is somewhat similar to this question, except the problem I am encountering is to do with Fourier transforms of scalar multiples of functions and their derivatives.

I wish to input FourierTransform[a*f[t],t,x] and have Mathematica simplify it to a*FourierTransform[f[t],t,x], and, equivalently, to input FourierTransform[f'[t],t,x] and have Mathematica simplify it to ix*FourierTransform[f[t],t,x]. I'm taking the Fourier transform of a system of differential equations for functions f[t],g[t], etc., in order to instead only have to solve a system of algebraic equations for their Fourier transforms, but Mathematica seems to be having some problems doing this.

Note that LaplaceTransform works exactly as expected, but for some reason FourierTransform doesn't perform the expected simplification. If someone could suggest a solution that also incorporates the distributive property that FourierTransform was shown to have a problem with in the question I linked, that would be ideal.

Example

This is essentially what I'd like FourierTransform to do:

LaplaceTransform[{a*f[t]+b*g'[t]==0,c*f'[t]+d*g[t]==0},t,x]

which returns:

{a*LaplaceTransform[f[t],t,x]+b*(-g[0]+x*LaplaceTransform[g[t],t,x])==0,
c*(-f[0]+x*LaplaceTransform[f[t],t,x])+d*LaplaceTransform[g[t],t,x]==0}

Instead, however, FourierTransform of the same expression returns:

{FourierTransform[a*f[t]+b*g'[t]==0,t,x],FourierTransform[c*f'[t]+d*g[t]==0,t,x]}

Edit

There is a solution to this problem here, although it doesn't actually explain FourierTransform's strange functionality.

Answer 1

The easiest work-around I can think of is to write a "shell" for the current FourierTransform:

ft[(h : List | Plus | Equal)[a__], t_, w_] := ft[#, t, w] & /@ h[a]
ft[a_ b_, t_, w_] /; FreeQ[b, Alternatives@@t] := b ft[a, t, w]
ft[a_, t_, w_] := FourierTransform[a, t, w]

ft[{a f[t] + b g'[t] == 0, c f'[t] + d e g[t] h[t] == 0}, t, w]

{a FourierTransform[f[t], t, w] - I b w FourierTransform[g[t], t, w] == 0, 
 -I c w FourierTransform[f[t], t, w] + d e FourierTransform[g[t] h[t], t, w]== 0}

Not sure if this will fail in more complicated cases.

---

In the code above I've only implemented the rules that are useful for solving differential equations, but it's not hard to include other properties of Fourier transform following the same method, for example:

(* Displacement property <- is this the right terminology? *)
ft[f_[t_] E^(Complex[0, c_] b_ t_), t_, w_] /; FreeQ[b, t] := ft[f[t], t, w + c b]
(* Convolution property *)
ft[a_[t_] b_[t_], t_, w_] := 
  Module[{x}, Hold[Convolve][ft[a@t, t, x], ft[b@t, t, x], x, w]/Sqrt[2 Pi]]

ft[E^(-I t Ω) a[t], t, w]

FourierTransform[a[t], t, w - Ω]

(* Verify the correctness: *)
FourierTransform[E^(-I t Ω) a[t], t, w] == % /. a -> (Exp[-#^2]&) // Simplify

True

ft[a[t] b[t], t, w]

(1/Sqrt[2 π]) Hold[Convolve][FourierTransform[a[t], t, x$60844], 
 FourierTransform[b[t], t, x$60844], x$60844, w]

(* Verify the correctness: *)
% == FourierTransform[a[t] b[t], t, w] /. {a -> (Exp[-#^2] &), b -> (Exp[-3 #^2] &)} // 
  ReleaseHold // Simplify

True

---

When dealing with high dimensional problem, the current behavior of FourierTransform is inconvenient:

FourierTransform[D[f[x, y], x, y], {x, y}, {wx, wy}]
(* -I wx FourierTransform[
          FourierTransform[Derivative[0, 1][f][x, y], x, wx], 
          y, wy] *)

What if I need

-wx wy FourierTransform[f[x, y], {x, y}, {wx, wy}]

as the output? We can add the following rule:

ft[Derivative[i__][h_][var__], {t__}, {w__}] := 
 With[{truefalse = FreeQ[Alternatives@t] /@ {var} // Boole}, 
  Times @@ Pick[(-I {var})^{i}, truefalse, 0] ft[(Derivative @@ ({i} truefalse))[h][
     var], {t}, {w}]]

ft[a D[f[t, x, y], x, y] + b D[g[x, y], x, x] + c D[h[y], y], {x, y}, {wx, wy}]

 -a x y FourierTransform[f[t, x, y], {x, y}, {wx, wy}] - 
  b x^2 FourierTransform[g[x, y], {x, y}, {wx, wy}] - 
  I c y FourierTransform[h[y], {x, y}, {wx, wy}]

---

Since v12.3 we can also use BilateralLaplaceTransform instead of FourierTransform. See this post for more info.