2
$\begingroup$

Consider the fourier transform

FourierTransform[1/((Cosh[x] + 1) (Cosh[x]^2 - 1)^(1/2)), x, w]

If I execute the above line, Mathematica thinks for several minutes and then returns the input back. If the input were returned immediately, that would probably mean that no transform can be obtained. However, since it takes a lot of time, it seems that Mathematica is calculating something but gives up after a timeout. This makes some hope that a transform actually exists. Is there any way I can still use Mathematica to get that fourier transform?

$\endgroup$
  • $\begingroup$ Did you consult classic tables as: people.math.sfu.ca/~cbm/aands or authors.library.caltech.edu/43489/1/Volume%201.pdf ? $\endgroup$ – Dimitris Apr 5 '17 at 14:29
  • $\begingroup$ @dimitris Thank you for the links. I searched the tables but could not find the result in them. $\endgroup$ – Kagaratsch Apr 5 '17 at 14:42
  • $\begingroup$ I gave a try with Mathematica 10. I guess Mathematica tries very hard, but after failing to evaluate something it gives up. Did you try tricks like the convolution theorem? Do you really need a closed form expression? The integral can be evaluated numerically. Also, what is the range of values of x? $\endgroup$ – Dimitris Apr 5 '17 at 14:48
  • $\begingroup$ @dimitris currently trying convolution method, wonder what the $P_\nu(\cos(a))$ function is in (7) on page 30 of authors.library.caltech.edu/43489/1/Volume%201.pdf . I think range in x is always $(-\infty,\infty)$ in a fourier transform? If I try numerics it says the integral diverges. $\endgroup$ – Kagaratsch Apr 5 '17 at 14:59
  • 2
    $\begingroup$ @Kagaratsch. $P_{\nu}(\cos(a))$ is likely LegendreP[ν, Cos[a]]. $\endgroup$ – march Apr 5 '17 at 16:03
3
$\begingroup$

First, let's look at

Series[1/((Cosh[x] + 1) (Cosh[x]^2 - 1)^(1/2)), {x, 0, 1}]

$\frac{1}{2 x}-\frac{5 x}{24}+O\left(x^2\right)$

The singularity of the integrand is of the form $1/(2x)$, with opposite sign for $x\to-x$, and will lead to a Fourier transform that doesn't have compact support, because

FourierTransform[1/Abs[x], x, w]

(* ==> (-2 EulerGamma - 2 Log[Abs[w]])/Sqrt[2 Pi] *)

(see also the plot below). But I think you can in fact get the analytical result as follows:

Let $F(\omega)$ be the desired Fourier transform, and $f(x)$ be the function in the question. Then

$$F(\omega )=\frac{1}{\sqrt{2\pi}}\left[\int_{-\infty}^0f(x)\,e^{i\omega x}\,dx+\int_0^{\infty}f(x)\,e^{i\omega x}\,dx\right]$$

In the first integral, change $x\to-x$,

$$F(\omega )=\frac{1}{\sqrt{2\pi}}\left[\int_0^{\infty}f(-x)\,e^{-i\omega x}\,dx+\int_0^{\infty}f(x)\,e^{i\omega x}\,dx\right]$$

Now use the symmetry $f(-x)=f(x)$ and denote $s\equiv i\omega$. Then

$$F(\omega )=\frac{1}{\sqrt{2\pi}}\left[\int_0^{\infty}f(x)\,e^{-s x}\,dx+\int_0^{\infty}f(x)\,e^{s x}\,dx\right]$$

which can be translated into LaplaceTransform:

ft1[w_] = 
 LaplaceTransform[1/((Cosh[x] + 1) (Cosh[x]^2 - 1)^(1/2)), x, s] /. s -> I w;

ft[w_] := 1/Sqrt[2 Pi] (ft1[w] + ft1[-w])

ft[w]

(*
==> (1/Sqrt[2 Pi])((1/(
  4 (1 - I w)))(-1 - I w - 6 w^2 + 
    2 (1 - I w) (-1 - 2 w^2) HarmonicNumber[1/2 (-1 - I w)] + 
    4 (1 - I w) w^2 HarmonicNumber[
      1 - I w] + (1 - I w) (-1 - 2 w^2) Log[4]) + (1/(
  4 (1 + I w)))(-1 + I w - 6 w^2 + 
    2 (1 + I w) (-1 - 2 w^2) HarmonicNumber[1/2 (-1 + I w)] + 
    4 (1 + I w) w^2 HarmonicNumber[
      1 + I w] + (1 + I w) (-1 - 2 w^2) Log[4]))
*)

Plot[ft[w], {w, -100, 100}]

$\endgroup$

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.