How to define an expression which is differently evaluated in calculations and printed

Question

Let's say, we have a list:

values = {1.2, 0.04, 0.9};

Is it possible to replace 0.04 by some expression, which displays as nearly zero when printed, but evaluates still to 0.04 when inserted into another Mathematica expression? I tried

values = {1.2, Interpretation["nearly zero",0.04], 0.9};

but this does not work. Although

Print[values];

indeed gives as output

{1.2,nearly zero,0.9}

but numericalValues = 1+values evaluates to

{2.2,1+"nearly zero",1.9}

not the expected

{2.2,1.04,1.9}

Answer 1

You need to define how you expect this special object to interact with functions, and which functions should handle it. Based on your example I think you want the label to be stripped from the object when an operation is performed?

• You can generally use UpSet or TagSet (or more frequently their Delayed counterparts) to provide handling rules as needed.

• Display is most robustly handled by defining a MakeBoxes rule for your object but Format can work too.

Perhaps you only want a limited number of functions to operate on your object. Then:

MakeBoxes[note[val_, name_], form_] := ToBoxes[name, form]

note /: note[val_, name_] + x_. := val + x
note /: note[val_, name_] * x_. := val * x

Now:

values = {1.2, note[0.04, "nearly zero"], 0.9}

{1.2, "nearly zero", 0.9}

1 + values

{2.2, 1.04, 1.9}

Or if you want most functions to operate in this manner you can choose which heads "hold" your object unevaluated:

ClearAll[note]

MakeBoxes[note[val_, name_], form_] := ToBoxes[name, form]

$noteHolders = {List, foo};

note /: head_[a___, note[val_, name_], b___] := 
  head[a, val, b] /; FreeQ[$noteHolders, head]

The global variable $noteHolders is a list of Symbols that should not evaluate note when the appear as the head of an expression. It may be updated at will if you define or find new functions that need to hold note unevaluated.

Test:

values = {1.2, note[0.04, "nearly zero"], 0.9}
1 + values

{1.2, "nearly zero", 0.9}

{2.2, 1.04, 1.9}

foo[1.2, note[0.04, "nearly zero"], 0.9]
bar[1.2, note[0.04, "nearly zero"], 0.9]

foo[1.2, "nearly zero", 0.9]

bar[1.2, 0.04, 0.9]

If you want to be able copy the output "nearly zero" and use it as input you will need to create an InterpretationBox in the MakeBoxes rule; see for example:

• How can one define a custom data object?

• How can I make Which format its output?

• Displaying index as subscript on output: e.g. C[i] -> C_i with Notation[...] or Interpretation[..]?

• Showing AlgebraicNumber[1/2 (1 + Sqrt[5]), {-3, 2}] in human-readable way

• Why doesn't a Composition[] hold its arguments and what can be done about it?

• Display All Output Numbers in HEX

Also however see this warning about the loss of "editability" that will result:

• Why does TraditionalForm[Inactivate[x y]] show x * y ? instead of x y?