How to place a matrix under controls (sliders) in a Manipulate?

Question

I want to know how I can place a matrix under my sliders. Here is my code:

Manipulate[
  Column[{
    Style[{{a, 0, 0}, {0, b, 0}, {0, 0, c}} // MatrixForm, 
      FontSize -> 18, FontColor -> Black, TextAlignment -> Left],
    Graphics3D[{GraphicsComplex[streckung[a, b, c], Polygon[i]]}, 
      Axes -> True, Boxed -> True, 
      PlotRange -> {{-5, 5}, {-5, 5}, {-5, 5}}, 
      ImageSize -> {{400, 400}}]}, Dividers -> {False, 2 -> Gray}],
  {{a, 1, "x-Richtung"}, -3, 3},
  {{b, 1, "y-Richtung"}, -3, 3},
  {{c, 1, "z-Richtung"}, -3, 3},
  ControlPlacement -> Left,
  Initialization :> (
    k := PolyhedronData["Cube", "VertexCoordinates"];
    Short[i = PolyhedronData["Cube", "FaceIndices"]];
    streckung[a_, b_, c_] := k.{{a, 0, 0}, {0, b, 0}, {0, 0, c}};
  ;)]

And here is a photo how it should look like:

Answer 1

As hinted in the comment, you might try it this way:

Manipulate[
  Column[{Style[{{a, 0, 0}, {0, b, 0}, {0, 0, c}} // MatrixForm, 
  FontSize -> 18, FontColor -> Black, TextAlignment -> Left], 
  Graphics3D[{GraphicsComplex[streckung[a, b, c], Polygon[i]]}, 
  Axes -> True, Boxed -> True, 
  PlotRange -> {{-5, 5}, {-5, 5}, {-5, 5}}, 
  ImageSize -> {{400, 400}}]}, Dividers -> {False, 2 -> Gray}], 
  Column[{
     Control@{{a, 1, "x-Richtung"}, -3, 3}, 
     Control@{{b, 1, "y-Richtung"}, -3, 3}, 
     Control@{{c, 1, "z-Richtung"}, -3, 3}, 
     Dynamic@Style[{{a, 0, 0}, {0, b, 0}, {0, 0, c}} // MatrixForm, 
         FontSize -> 18, FontColor -> Black, TextAlignment -> Left]}], 
  ControlPlacement -> Left, 
  Initialization :> (k := PolyhedronData["Cube", "VertexCoordinates"];
  Short[i = PolyhedronData["Cube", "FaceIndices"]];
  streckung[a_, b_, c_] := k.{{a, 0, 0}, {0, b, 0}, {0, 0, c}};)]

and you get:

Viel Erfolg!