How to extract data beginning on the closest number to zero?

Question

I have a list from which I want to extract only the values beginning from where b (from {a,b}) is the closest to zero. For example:

I want to extract

data={{2, -0.036704}, {56.7499, 0.95489}, {73.7349, 0.73489}, {2, -0.237504}}

from the following list:

list = {{1, 0.67342}, {77.7499, -0.93489}, {6.73448, 0.056704}, {2, -0.036704}, 
 {56.7499, 0.95489}, {73.7349, 0.73489}, {2, -0.237504}}

Thanks in advance

Answer 1

One way is to find the index ind where the minimum occurs, and then take all the remaining elements of the list:

ind = First@Ordering[First@Abs[Rest[Transpose[list]]]];
list[[ind ;;]]
{{2, -0.036704}, {56.7499, 0.95489}, {73.7349, 0.73489}, {2, -0.237504}}

Answer 2

An alternative to find the starting index is to use Nearest:

ind = First @ Nearest[Last @ Transpose @ list -> "Index", 0];
list[[ind;;]]

{{2, -0.036704}, {56.7499, 0.95489}, {73.7349, 0.73489}, {2, -0.237504}}

For larger datasets, Nearest is faster:

data = RandomReal[{-100, 100}, {10^6, 2}];
second = Last @ Transpose @ data;

r1 = First @ Nearest[second -> "Index", 0] //RepeatedTiming
r2 = First @ Ordering[Abs @ second, 1] //RepeatedTiming 

{0.0018, 725110}

{0.0062, 725110}