Plot with ScalingFunctions->{"Infinite",interval}

Question

Consider the plot

The X-axis presents a log-scale, left-extended from Zero and right-extended to Infinity, with focus on the interval {2,50}. It conveys the information that the functions are 0 at the origin and tend asymptotically to 1.

Q: Is there a way to change the "focused interval" from {2,50} to something else, like {.001,5}?

---

I would like to draw a plot with logarithmic scale on the X-axis, and linear scale on the Y-axis; the X-axis going to Infinity, while focusing on a specific interval.

Consulting the documentation of Plot/Options/ScalingFunctions, I found out that ScalingFunctions->{"OptA","OptB"} would apply "OptA" scaling to the X-axis and "OptB" to the Y-axis.

Consulting the documentation of ScalingFunctions/Details, I figured the option
{"Infinite",interval}, to

show asymptotic behavior by compressing infinite ranges into finite ranges

by setting an

infinite scale focused on interval

was what I was looking for my X-axis.

I tried

Plot[{F[.25, 0, t], F[.25, .1, t], F[.25, .2, t]}, {t,0, Infinity}, 
  ScalingFunctions -> {{"Infinite", {.001, 50}}, None}, 
  PlotRange -> {0, 1.5}, PlotLegends -> Placed[{"a=0", "a=0.1", "a=0.2"}, {.9, .3}]]

which yielded the output shown in the above image.

---

Function:

lam[pi2_] := 1/(2 pi2 - 1);
gama[pi2_, a_, t_] := 1 - Exp[lam[pi2]*t] + 2 lam[pi2]^2*t*(pi2 - a)*Exp[lam[pi2]*t];
F[pi2_, a_, t_] := pi2 (1 - pi2)/(pi2 - Exp[lam[pi2]*t] (pi2 - a))/
  (1 - pi2 + Exp[lam[pi2]*t] (pi2 - a))*gama[pi2, a, t]^2

Answer 1

$Version

(* "13.3.1 for Mac OS X ARM (64-bit) (July 24, 2023)" *)

Clear["Global`*"]

lam[pi2_] := 1/(2 pi2 - 1);
gama[pi2_, a_, t_] := 
  1 - Exp[lam[pi2]*t] + 2 lam[pi2]^2*t*(pi2 - a)*Exp[lam[pi2]*t];
F[pi2_, a_, t_] := 
 pi2 (1 - pi2)/(pi2 - Exp[lam[pi2]*t] (pi2 - a))/(1 - pi2 + 
     Exp[lam[pi2]*t] (pi2 - a))*gama[pi2, a, t]^2

Using Inset

Plot[Evaluate[F[.25, #, t] & /@ {{0, 0.1, 0.2}}],
 {t, 0, Infinity},
 PlotRange -> {0, 1.5},
 PlotLegends -> Placed[{"a=0", "a=0.1", "a=0.2"}, {.9, .85}],
 Epilog -> Inset[
   LogLinearPlot[Evaluate[F[.25, #, t] & /@ {{0, 0.1, 0.2}}],
    {t, 0.01, 5},
    PlotRange -> {0, 1.5},
    ImageSize -> Medium],
   {.5, .495}],
 ImageSize -> Large,
 Frame -> True]

EDIT: I don't know how to do what you want. However, if your primary interest is the interval {0.001, 5} use either

a = {0, 1/10, 1/5};

funcs = (F[1/4, #, t] & /@ a) // Simplify;

plt = Plot[Evaluate[Tooltip /@ funcs],
  {t, 0, 5},
  PlotRange -> {{0, 5}, {0, 1.5}},
  PlotRangePadding -> Scaled[.05],
  PlotLegends -> Placed[LineLegend[N@a,
     LegendLabel -> Style[HoldForm[a], 14]], {.9, .3}],
  GridLines -> {None, {1}},
  GridLinesStyle -> Directive[AbsoluteThickness[0.75], Gray, Dashed]]

plt = LogLinearPlot[Evaluate[Tooltip /@ funcs],
  {t, 0.001, 5},
  PlotRange -> {0, 1.5},
  PlotRangePadding -> Scaled[.05],
  PlotLegends -> Placed[LineLegend[N@a,
     LegendLabel -> Style[HoldForm[a], 14]], {.9, .3}],
  GridLines -> {None, {1}},
  GridLinesStyle -> Directive[AbsoluteThickness[0.75], Gray, Dashed]]

Answer 2

You do not need scaling functions for this. For the most common cases there are ready made functions. For your case , you would want: "LogLinearPlot".

Then I do not get the same plot as you. For t->Infiniy the functions -> zero.

Further, if the x axis is logarithmic, it can not start at zero, because this is at infinity.

Here is a plot of your functions from 10^-2 to 5:

M1 = LogLinearPlot[{F[.35, 0, t], F[.25, .1, t], F[.25, .2, t]}, {t, 
   10^-2, 5}, PlotRange -> All, 
  PlotLegends -> Placed[{"a=0", "a=0.1", "a=0.2"}, {.9, .7}]]