Disable editing for graphics

Question

I am creating an interactive graphics that plots points on the canvas, and allows the user to move around the points:

DynamicModule[
 {pt1 = {-2, 1}, pt2 = {2, 2}, pt3 = {2, -2}}
 ,
 Framed@Graphics[
   {Locator[Dynamic[pt1]],
    Locator[Dynamic[pt2]],
    Locator[Dynamic[pt3]],
    Dynamic[BezierCurve[{pt1, pt2, pt3}]]
    }
   , PlotRange -> 3]
 ]

It works fine, but I noticed that if one misses a bit the click with the mouse to move one of the points, Mathematica mistakenly suggests to edit the Graphics object. It happens during the point movement in the following screenshot (Note the tooltip "Double Click to edit"):

Is there any way to disable editing for Graphics?

Answer 1

• Deploy seems work.

DynamicModule[{pt1 = {-2, 1}, pt2 = {2, 2}, pt3 = {2, -2}}, 
 Deploy@Dynamic@
   Framed@Graphics[{Locator[Dynamic@pt1], Locator[Dynamic@pt2], 
      Locator[Dynamic@pt3], Dynamic@BezierCurve[{pt1, pt2, pt3}]}, 
     PlotRange -> 3]]

• Another way is use LocatorPane.

DynamicModule[{pts = {{-2, 1}, {2, 2}, {2, -2}}},
 LocatorPane[Dynamic@pts, 
  Dynamic@Graphics[BezierCurve@pts, PlotRange -> 3, Frame -> True, 
    FrameTicks -> None]]]