ParametricRegion and ImplicitRegion surface integral help

Question

I use these two methods (ParametricRegion and ImplicitRegion) to define the integral region and calculate the surface integral, but why do I get different results?

ParametricRegion:

Clear["Global`*"];
f[x_, y_] := 1/Sqrt[a^2 - x^2 - y^2];
F[x_, y_] := Sqrt[a^2 - x^2 - y^2];
t[x_, y_] = Sqrt[1 + D[F[x, y], x]^2 + D[F[x, y], y]^2]
s[r_, \[Phi]_] = 
 Simplify[f[x, y]*t[x, y] /. {x -> r Cos[\[Phi]], y -> r Sin[\[Phi]]},
   Assumptions -> a >= r > 0]
reg = ParametricRegion[{r*Cos[\[Phi]], 
    r*Sin[\[Phi]]}, {{\[Phi], 0, 2 \[Pi]}, {r, 0, Sqrt[a^2 - h^2]}}];
r*s[r, \[Phi]] // Simplify
Integrate[r*s[r, \[Phi]], Element[{r, \[Phi]}, reg], 
 Assumptions -> 0 < h < a]

(*Wrong result:  0*)

ImplicitRegion:

Clear["Global`*"];
f[x_, y_] := 1/Sqrt[a^2 - x^2 - y^2];
F[x_, y_] := Sqrt[a^2 - x^2 - y^2];
t[x_, y_] = Sqrt[1 + D[F[x, y], x]^2 + D[F[x, y], y]^2]
s[r_, \[Phi]_] = 
 Simplify[f[x, y]*t[x, y] /. {x -> r Cos[\[Phi]], y -> r Sin[\[Phi]]},
   Assumptions -> a >= r > 0]
reg = ImplicitRegion[
   0 <= \[Phi] <= 2 Pi && 0 <= r <= Sqrt[a^2 - h^2], {r, \[Phi]}];
r*s[r, \[Phi]] // Simplify
Integrate[r*s[r, \[Phi]], Element[{r, \[Phi]}, reg], 
 Assumptions -> 0 < h < a]

(*Correct result:  2 a \[Pi] Log[a/h]*)

Answer 1

Thanks for Ulrich Neumann's comments. I found the answer. It's a mistake :)

ParametricRegion:

Clear["Global`*"];
f[x_, y_] := 1/Sqrt[a^2 - x^2 - y^2];
F[x_, y_] := Sqrt[a^2 - x^2 - y^2];
t[x_, y_] = Sqrt[1 + D[F[x, y], x]^2 + D[F[x, y], y]^2]
s[r_, \[Phi]_] = 
 Simplify[f[x, y]*t[x, y] /. {x -> r Cos[\[Phi]], y -> r Sin[\[Phi]]},
   Assumptions -> a >= r > 0]
reg = ParametricRegion[{r, \[Phi]}, {{\[Phi], 0, 2 \[Pi]}, {r, 0, 
     Sqrt[a^2 - h^2]}}];
r*s[r, \[Phi]] // Simplify
Integrate[r*s[r, \[Phi]], Element[{r, \[Phi]}, reg], 
 Assumptions -> 0 < h < a]

(*2 a \[Pi] Log[a/h]*)

Or,

Clear["Global`*"];
f[x_, y_] := 1/Sqrt[a^2 - x^2 - y^2];
F[x_, y_] := Sqrt[a^2 - x^2 - y^2];
t[x_, y_] := Sqrt[1 + D[F[x, y], x]^2 + D[F[x, y], y]^2];
reg = ParametricRegion[{r*Cos[\[Phi]], 
    r*Sin[\[Phi]]}, {{\[Phi], 0, 2 \[Pi]}, {r, 0, Sqrt[a^2 - h^2]}}];
Integrate[f[x, y]*t[x, y], Element[{x, y}, reg], 
 Assumptions -> 0 < h < a]

(*2 a \[Pi] Log[a/h]*)