How to find elements in a list by last two elements

Question

I have a list list= {{a1, b1, c1}, {a2, b2, c2}, {a3, b3, c3},......} in which I want to find the element "an" by giving the values of {bn, cn} in the same order.

For example, if

list = {{1, 2, 3}, {4, 5, 6}, {7, 6, 5}}

For {5, 6}, I should get 4, not 7.

Thanks

Answer 1

list = {{1, 2, 3}, {4, 5, 6}, {7, 6, 5}};
asso = GroupBy[list, Rest -> First];
asso[{5, 6}]
(* {4} *)

If any $\{b_n, c_n\}$ occurs at most once, it's not necessary to have a list returned:

asso = GroupBy[list, Rest -> First, First];
asso[{5, 6}]
(* 4 *)

Answer 2

A simplified version of @kglr's function:

f[b_, c_] := Cases[list, {a_, b, c} -> a]

f[5, 6]
(*    {4}    *)

If you are sure that there is only one matching case, you can gain some speed by replacing Cases with FirstCase:

g[b_, c_] := FirstCase[list, {a_, b, c} -> a]

g[5, 6]
(*    4    *)

Answer 3

list//Pick[#[[All,1]],#[[All,2;;]], {5,6}]&

{4}

Answer 4

list = {{1, 2, 3}, {4, 5, 6}, {7, 6, 5}};

Using Extract

p = Append[1] /@ Position[list, {__, 5, 6}]

{{2, 1}}

Extract[list, p]

{4}

Answer 5

list = {{1, 2, 3}, {4, 5, 6}, {7, 6, 5}};

Using SequenceCases:

SequenceCases[list, {s : {_, 5, 6}} :> First@s]

(*{4}*)