Find elements of a list matching specific patterns

Question

I have defined several symbolic function f[x],g[x,y],h[x,y,z] etc... And I have a list made of elements which are product of these functions with different arguments; for example,

list = { f[a]f[-a], f[a]g[c,d]h[-a,-c,-d],  f[c]f[-c] ,
       f[d]g[a,y]h[-d,-a,-y] , f[b]f[-a] , f[-c]f[c] ,
       f[d]g[a,y]h[-d,-a,-z] }

Actually, these functions are just symbolic. They do not return any value. You can think the functions' arguments as tensorial indexes.

I want to find an efficient function checkPattern[list_] which does the following

1) Take the first element f[a]f[-a] and find if there are others elements matching this pattern; so, for example, the third element of list is "equal" to the first one, in the sense that f[a]f[-a]~f[c]f[-c]~f[-c]f[c] irrespectively of the arguments. Note that the elements f[a]f[-a] and f[b]f[-a] are different.

2) Take the second element (which is more complicated) and does the same check as the step 1.

So the result would be

checkPattern[list]
(* {{1,3,6},{2,4},{5},{7}}*)

Answer 1

Here is your list:

list = {f[a] f[-a], f[a] g[c, d] h[-a, -c, -d], f[c] f[-c], 
   f[d] g[a, y] h[-d, -a, -y], f[b] f[-a], f[-c] f[c], 
   f[d] g[a, y] h[-d, -a, -z]};

Borrowing from here, we can find a list of all distinct patterns as follows:

patterns = Quiet[
   SortBy[
    DeleteDuplicates[
     list /. 
      p : Alternatives[a | b | c | d | x | y | z] :> 
       Pattern[p, Blank[]],
     Internal`ComparePatterns[##] == "Identical" &
     ],
    MemberQ[{"Identical" , "Specific"}, Internal`ComparePatterns[##]] &]
   ];

Observe that I had to specify which symbols may be used as "indices".

A first approximation to the ultimate result could be

allpos = Map[Flatten@Position[list, #] &, patterns]

{{1, 3, 6}, {1, 3, 5, 6}, {2, 4}, {2, 4, 7}}

This can be cleaned up by utilizing that patterns is already ordered:

Table[Complement[allpos[[i]], Union @@ allpos[[1 ;; i - 1]]], {i, 1, Length[allpos]}]

{{1, 3, 6}, {5}, {2, 4}, {7}}