Reduce doesn't work with user defined function with /;

Question

I want to use Reduce to my own function, but it generates the error message: This system cannot be solved with the methods available to Reduce. Here is a simplified example.

test[x_] := x^2 - 3 /; 0<x<10;
test[x_] := -1 /; 10<x

Reduce[test[x]<1, 0<x<5]

I think /; makes the problem. However, how can I define the domain of my own function without using /;?

Answer 1

To summarize insightful comments, Piecewise is the appropriate construct to express the mathematical idea of a piecewise function, as Natas suggested. Condition (i.e. /;) is a programming construct. As Szabolcs mentioned, "it is not meant to represent mathematical ideas; it is meant to implement algorithms". In the following, note also the corrected syntax for Reduce.

Clear[test]
test[x_] := Piecewise[{{x^2 - 3, 0 < x < 10}, {-1, x > 10}}]
Reduce[test[x] < 1 && 0 < x < 5, x]

(* Out: 0 < x < 2 *)

As an alternative approach, Bill proposed using Boole:

Clear[test]
test[x_] := ((x^2 - 3)*Boole[0 < x < 10]) + (-1*Boole[10 < x]); 
Reduce[test[x] < 1 && 0 < x < 5, x]

(* Out: 0 < x < 2 *)