How to calculate Inverse Fourier Transform and cancel out things like HeavisideTheta (so, the function looks exactly like the initial notation)

Question

my question has two parts (please check everything for any mistakes):

The Fourier transform of

FourierTransform[Exp[-a Abs[t]], t, ω, 
 FourierParameters -> {1, -1}]=(2 a)/(a^2 + ω^2)

which is the correct answer.

1.How to get its Inverse Fourier Transform correctly?

InverseFourierTransform[2 a/((a^2) + (ω^2)), ω, t, 
 Assumptions -> a > 0 , FourierParameters -> {1, -1}]=E^(a t) HeavisideTheta[-t] + E^(-a t) HeavisideTheta[t]

is it correct?

2. How to display the Inverse Fourier Transform without any HeavisideTheta?(or anything else which makes the answer different from the initial function) so the answer looks like the initial theoretical notation: Exp[-a Abs[t]].

Thanks

Answer 1

$Version

"12.1.0 for Mac OS X x86 (64-bit) (March 14, 2020)"

Clear["Global`*"]

expr = Exp[-a Abs[t]];

ft = FourierTransform[expr, t, ω, FourierParameters -> {1, -1}]

(* (2 a)/(a^2 + ω^2) *)

ift[t_] = InverseFourierTransform[ft, ω, t, Assumptions -> a > 0,
  FourierParameters -> {1, -1}]

(* E^(a t) HeavisideTheta[-t] + E^(-a t) HeavisideTheta[t] *)

Since HeavisideTheta is undefined at zero, the ift is equal to expr everywhere except for t == 0.

Simplify[expr == ift[t], #] & /@ {t < 0, t == 0, t > 0}

(* {True, 2 HeavisideTheta[0] == 1, True} *)

This is due to the fact that expr is not smooth for t == 0

Plot[expr /. a -> 1, {t, -3, 3}]

EDIT: For FourierParameters -> {1, -1}] the InverseFourierTransform is given by

ift[t_] = 1/(2 Pi) Integrate[
   ft E^(I ω t), {ω, -Infinity, Infinity},
   Assumptions -> {a > 0, Element[t, Reals]}]

(* E^(-a Abs[t]) *)

ift[t] == expr

(* True *)