1
$\begingroup$

I am new to Mathematica, and I am trying to simplify this expression when Y=1 and Y1 -> ∞

  X=2 * Pi * Y^2 * Y1 * Integrate[1/((Y^2 + s)^2 * Sqrt[(Y1^2 + s)]),{s,0,∞}]
$\endgroup$

3 Answers 3

2
$\begingroup$

Fixing syntax errors and adding assumptions on your variables:

Assuming[Y > 0 && Y1 > 0,
    X = 2 π Y^2 Y1 Integrate[1/((Y^2+s)^2*Sqrt[(Y1^2+s)]), {s,0,∞}]
];
X //TeXForm

$\frac{2 \pi Y \operatorname{Y1} \left(Y \cos ^{-1}\left(\frac{\operatorname{Y1}}{Y}\right)-\operatorname{Y1} \sqrt{1-\frac{\operatorname{Y1}^2}{Y^2}}\right)}{\left(Y^2-\operatorname{Y1}^2\right)^{3/2}}$

Then, replace Y with 1 and take the limit as Y1 goes to $\infty$:

Limit[X /. Y->1, Y1->∞]

2 π

Update

If you're interested in the Y and Y1 dependence for large Y1, you could do:

Series[X,{Y1,Infinity,2},Assumptions->Y>0] //TeXForm

$2 \pi +\frac{2 \pi Y^2}{\operatorname{Y1}^2}+O\left(\left(\frac{1}{\operatorname{Y1}}\right)^3\right)$

$\endgroup$
1
  • $\begingroup$ Thank you so much! $\endgroup$
    – Math
    Apr 19, 2018 at 17:27
2
$\begingroup$

A new EXPERIMENTAL function in version 11.3 is AsymptoticIntegrate

$Version

"11.3.0 for Mac OS X x86 (64-bit) (March 7, 2018)"

X = 2*Pi*Y^2*Y1*
  AsymptoticIntegrate[
   1/((Y^2 + s)^2*Sqrt[(Y1^2 + s)]), {s, 0, ∞}, {Y1, Infinity, 1}]

(* 2 π *)

X = 2*Pi*Y^2*Y1*
   AsymptoticIntegrate[
    1/((Y^2 + s)^2*Sqrt[(Y1^2 + s)]), {s, 0, ∞}, {Y1, Infinity, 
     3}] // FullSimplify

(* 2 π (1 + Y^2/Y1^2) *)
$\endgroup$
1
  • $\begingroup$ Thank you so much $\endgroup$
    – Math
    Apr 19, 2018 at 22:11
1
$\begingroup$

Quite simple. As $Y=1$, then $X$ simplifies to:

$Version

11.3.0 for Mac OS X x86 (64-bit) (March 7, 2018)

X=2*Pi*Y1*Integrate[1/((1 + s)^2*Sqrt[Y1^2 + s]), {s, 0, Infinity}]

$$\text{ConditionalExpression}\left[\frac{\pi \text{Y1} \sqrt{\text{Y1}^2} \left(\pi \sqrt{\frac{1}{\text{Y1}^2}}-2 \sqrt{1-\text{Y1}^2}-\frac{2 \sin ^{-1}(\text{Y1})}{\text{Y1}}\right)}{\left(1-\text{Y1}^2\right)^{3/2}},\Re\left(\text{Y1}^2\right)>0\right]$$

Now, taking limit when $Y1\rightarrow\infty$:

Limit[X, Y1 -> \[Infinity]]

$2\pi$

$\endgroup$
1
  • $\begingroup$ Thank you so much! $\endgroup$
    – Math
    Apr 19, 2018 at 17:28

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service and acknowledge you have read our privacy policy.

Not the answer you're looking for? Browse other questions tagged or ask your own question.