Simplifying a trig expression

Question

How can I get Mathematica to simplify the following expression?

Pi-ArcCos[-1/Sqrt[3]]

I'd like the answer to be ArcCos[1/Sqrt[3]], which seems manifestly "simpler" to me. If I use Simplify, it leaves it as it is. A related question is: howcome

Pi-ArcCos[-1/Sqrt[3]]==ArcCos[1/Sqrt[3]]

does not return True or False, but rather returns back the same expression?

Answer 1

Clear["Global`*"]

expr = Pi - ArcCos[-1/Sqrt[3]];

The simplification is available in MathematicalFunctionData

argSimp = (MathematicalFunctionData["ArcCos", 
       "ArgumentSimplifications"][[1]][z] // Activate) /. Equal :> Rule

(* ArcCos[-z] -> π - ArcCos[z] *)

expr /. (argSimp /. z :> 1/Sqrt[3])

(* ArcCos[1/Sqrt[3]] *)

EDIT: Use ComplexExpand to test the equality

Pi - ArcCos[-1/Sqrt[3]] == ArcCos[1/Sqrt[3]] // ComplexExpand

(* True *)

Answer 2

I would claim that your expected form is not the simplest one. I would instead propose $$ \tan ^{-1}\left(\sqrt{2}\right) $$ and do the simplification as follows

e = Pi - ArcCos[-1/Sqrt[3]];
es = ArcTan[Tan[e]]
FullSimplify[e==es]
(* ArcTan[Sqrt[2]] *)
(* True *)