Simplifying this ArcTan sum expression

Question

$Assumptions = Element[t, Reals] && Element[ω, Reals] && ω > 0 
&& t > 0;
ArcTan[8.54596*10^7 (1. + 1. t^2 ω^2) (1.2214 + E^ω Cos[
2 ArcTan[t ω]]), -1.70919*10^8 E^ω t ω] + 
ArcTan[8.54596*10^7 (1. + 1. t^2 ω^2) (1.2214 + E^ω 
Cos[2ArcTan[t ω]]),1.70919*10^8 E^ω t ω]//FullSimplify

Mathematica doesn't simplify this seemingly ArcTan[x,y]+ArcTan[x,-y] expression. I plotted the 3D-graph, it shows the expression is zero for all values of t and \[Omega].

I understand one underlying reason might be Mathematica isn't sure about the positivity of Cos term in x, and hence, x. Am I right? Any ideas to simplify this term in code, instead of manually, would be very much appreciated. I'm relatively new to the language.

Answer 1

First you should avoid using inexact numbers if possible.

expr = ArcTan[ α (1 +  t^2 ω^2) (γ +E^ω Cos[2 ArcTan[t ω]]), -β E^ω t ω] + 
  ArcTan[α(1 +  t^2 ω^2) (γ + E^ω Cos[2 ArcTan[t ω]]), β E^ω t ω]

Now, with assumptions inside , the simplification evaluates as you expect

Simplify[expr, 
Assumptions -> {ω > 0,t > 0 , α > 0, β > 0, γ >0,Cos[2 ArcTan[t ω]] > 0,Elements[{ω, t, α, β,γ}, Reals]}]
(* 0 *)

Answer 2

$Assumptions = ω > 0 && t > 0;

Note that if a variable is positive it is redundant to add that it is real.

If you want exact results you must use exact numbers. Use Rationalize

expr = ArcTan[
     8.54596*10^7 (1. + 1. t^2 ω^2) (1.2214 + 
        E^ω Cos[
          2 ArcTan[t ω]]), -1.70919*10^8 E^ω t ω] + 
    ArcTan[8.54596*10^7 (1. + 1. t^2 ω^2) (1.2214 + 
        E^ω Cos[2 ArcTan[t ω]]), 
     1.70919*10^8 E^ω t ω] // Rationalize;

TrigToExp is what you need

expr // TrigToExp // Simplify

(* 0 *)