RegionFunction does not exclude regions between points of similar value

Question

RegionFunction is normally good at suppressing points in a plot:

ListPlot3D[Flatten[Table[{x, y, RandomReal[]*(x^2 + y^2)}, {x, -5, 5}, {y, -5, 5}], 1], 
RegionFunction -> ((#2 >= #1 && #2 >= -#1) || (#2 <= #1 && #2 <= -#1) &)]

Now consider this data, which is some random numbers over a diamond-shaped domain:

data = {#[[1]], #[[2]], #[[3]]*(#[[1]]^2 + #[[2]]^2)} & /@
   ({(#[[1]] - #[[2]])/2, (#[[1]] + #[[2]])/2, #[[3]]} & /@ 
   Flatten[Table[{x, y, RandomReal[0.1]}, {x, 0, 5}, {y, 0, 5}], 1]);
ListPlot3D[data, PlotRange -> {0, 5}]

Now let's mirror the data over the x-axis, and note that ListPlot3D will automatically plot the connecting regions between the two diamonds:

dataMirrored = DeleteDuplicates@Join[data, {#[[1]], -#[[2]], #[[3]]} & /@ data];
ListPlot3D[dataMirrored, PlotRange -> {All, All, {0, 5}}]

Now, it seems RegionFunction doesn't work - I guess this has something to do with the data taking similar values across the gap:

ListPlot3D[dataMirrored, PlotRange -> {0, 5}, 
   RegionFunction -> ((#2 >= #1 && #2 >= -#1) || (#2 <= #1 && #2 <= -#1) &)]

Even adding a small perturbations to all three coordinates of every point does not completely block this behavior:

ListPlot3D[{#[[1]] + RandomReal[10^-3], #[[2]] + RandomReal[10^-3], 
   #[[3]] + RandomReal[10^-3]} & /@ dataMirrored, PlotRange -> {0, 5},
    RegionFunction -> ((#2 >= #1 && #2 >= -#1) || (#2 <= #1 && #2 <= -#1) &)]

How can I get ListPlot3D to respect RegionFunction?

Answer 1

First of all, since I will be using quite a few ListPlot3D calls, I'd like to keep them all consistent and readable by introducing a wrapper function, myLP3D that sets a manual plot range and labels the axes, but passes any further optional argument through to the underlying ListPlot3D:

Clear[myLP3D]
myLP3D[pts_List, opts : OptionsPattern[ListPlot3D]] :=
  ListPlot3D[
    pts,
    PlotRange -> {{-5, 5}, {-5, 5}, Automatic},
    AxesLabel -> (Style[#, 14, Bold] & /@ {"x", "y", "z"}),
    Evaluate[FilterRules[{opts}, Options[ListPlot3D]]]
  ]

I generated some data on the same domain you were using, but I will not use random $z$ values: I find it irrelevant to your question and confusing because it leads to ugly, poorly readable surfaces. Instead, I will assign a constant $z=1$. I then generated a mirrored set as you specified ($y$ coordinate swapped sign). mirrored is actually a list of the two data sets, the original and the mirrored ones, so they can be readily visualized:

data =
  {(#1 - #2)/2, (#1 + #2)/2, 1} & @@@
   Flatten[Table[{x, y}, {x, 0, 5}, {y, 0, 5}], 1];

mirrored = {data, {#1, -#2, #3} & @@@ data};

GraphicsRow[{myLP3D[data], myLP3D[mirrored]}, ImageSize -> Full]

I then generate the joined set: all points from the mirrored set, but in a single list:

joined = DeleteDuplicates@Join[Sequence @@ mirrored];

As you showed, ListPlot3D "fills in" the region between the two data sets when drawing the corresponding surface:

myLP3D[joined]

As you showed, attempting to add a RegionFunction that described the domain of the two data sets does not seem to help (note that I rewrote your conditions as $|x|\le|y|$, which is equivalent to your formulation but more compact):

myLP3D[joined, RegionFunction -> (Abs[#1] <= Abs[#2] &)]

However, region function is not quite ignored: it is simply not checked thoroughly enough with the standard number of plot points. If you increase the MaxPlotPoints setting, the situation improves dramatically:

myLP3D[joined, RegionFunction -> (Abs[#1] <= Abs[#2] &), MaxPlotPoints -> 50]