Align stars in multiple images

Question

I hope that you find this question interesting and that this will help others with similar problems as this configuration is not so particular.

My problem

I have multiple images of a particular region in the sky. These images depict stars. In order to make measures i have to align the images first (to identify the same star in each image, for example). I'm finding this task extreamly difficult. This is what i have tried so far:

• First I tried to use ImageAlign with the two images, but it did not work. As the correction should be a translation, I also tried to giving TransformationClass -> "Translation" as an option, but that did not work.

• The best approach so far is the following:

• Binarize the images to show the stars more clearly.

• Identify the stars using MorphologicalComponents.

• Use FindGeometricTransormation with the coordinates of the stars to find a transformation using the option `TransformationClass -> "Translation".

This last approach work iff the images are very closely related.

Here is the link of the actual images and a binarize copy of them:

http://s28.postimg.org/mk78gibi3/Image1.png

http://s28.postimg.org/x5r3sihtn/Image2.png

http://s28.postimg(dot)org/o86dv5pdp/Binarize1.png

http://s28.postimg(dot)org/x4h5z3fzx/Binarize2.png

As the final objective is to automate the process, the less human input to the process the better.

Answer 1

UPDATED VERSION:

Import the images:

img1 = Import[NotebookDirectory[] <> "Image1.png"];
img2 = Import[NotebookDirectory[] <> "Image2.png"];
imgs = {img1, img2};
ImageCollage[imgs]

Binarize the two images using the "MinimumError"-Method, pad the images (hald the size of the original images) and perform an Opening to get rid of binarized background noise:

imgsbin = Opening[ImagePad[Binarize[#, FindThreshold[#, Method -> "MinimumError"]], 512], 1] & /@ imgs;
ImageCollage[imgsbin]

Dilate the binarized stars (original stars are obviously too small for ImageAlign to find an appropriate transformation, 20 seems to work well):

imgsbindil = Dilation[#, 20] & /@ imgsbin;
ImageCollage[imgsbindil]

Align the images:

imgal = ImageAlign[imgsbindil[[1]], imgsbindil[[2]], TransformationClass -> "Rigid", Method -> "Keypoints"];
ColorCombine[{imgsbindil[[1]], imgal}]

Erode the images back to normal object size:

ColorCombine[{Erosion[imgsbindil[[1]], 20], Erosion[imgal, 20]}]

Binarize the result:

% // Binarize

The method works quite well for the provided images, but the result depends on the image quality. This mainly affects stars that are cut by the image border (objects do not overlap properly, see bottom left in the final image).

Answer 2

Those listed below might more like a suggestion than an answer with a lot of handwork.

First import the img downloaded from your link.

img1 = Import@"D:\\...\\lteiaq94pImage2.png"; 
img2 = Import@"D:\\...\\peadtydo9Image1.png";

Binarize them with carefully chosed parameters:

img1bin = Erosion[Binarize[img1, 0.2], 0.4];
img2bin = Erosion[Binarize[img2, 0.4], 0.5];

img1bin and img2bin look like:

and

get ImageData:

img1bind = ImageData@img1bin; img2bind = ImageData@img2bin;

chose a sample for align:

Image@img2bind[[500 ;; -1, 1 ;; 500]]

which looks like:

define the coincide function:

data2 = img2bind[[500 ;; -1, 1 ;; 500]];
coincide[x_, y_] := 
Total[data2*img1bind[[500 - y ;; -1 - y, 1 + x ;; 500 + x]], 2]

search for the "most likely coincide area":

posi = Outer[coincide, Range[1, 450, 10], Range[1, 450, 10]]

find the position related to the "most likely coincide area":

Position[posi, Max[posi]]

which returned {{23, 15}}, define

img1cut[x_, y_] := 
Image[img1bind[[500 - y ;; -1 - y, 1 + x ;; 500 + x]]];

then we see

img1cut[231, 151]

gives the almost same four stars in sample:

you can refine the search grid(which is 10) at neighborhood of {231, 151} for more accurate result.