How to display operations on list elements

Question

When applying some arithmetic operation on two lists, I'd like to display the actual operations between the elements of each list. For example, {1, 1} + {1, -1} would display {1 + 1, 1 - 1}.

With simple operations, I could just use Trace and pick out the part with the right form:

Trace[{1, 1} + {1, -1}, {_Plus, _Plus}]
(* {{1+1,1-1}} *)

However, this becomes really cumbersome in more complex operations. Even worse, some operations don't even show element-by-element operations within Trace.

Trace[{{1, 2}, {3, 4}}.{{5, 6}, {7, 8}}]
(* {{{1,2},{3,4}}.{{5,6},{7,8}},{{19,22},{43,50}}} *)

This is what I actually want to display:

Of course I could programmatically display the element operation of the matrix multiplication above, but I have to do the same for every other matrix operations.

---

My question is: Is there a straightforward way to display operations on elements of two lists? Please feel free to add your own examples and make it as general as you want to.

Answer 1

This might be "too direct" an answer, but you can try:

Inner[Inactive[Times], {{1, 2}, {3, 4}}, {{5, 6}, {7, 8}}, Inactive[Plus]] // MatrixForm

$\left( \begin{array}{cc} 1*5+2*7 & 1*6+2*8 \\ 3*5+4*7 & 3*6+4*8 \\ \end{array} \right)$

Answer 2

For version 9 (and possibly older versions), you can use

Inner[Composition[Defer, Times], {{1, 2}, {3, 4}}, {{5, 6}, {7, 8}}] // MatrixForm

or

Inner[Defer[Times@##] &, {{1, 2}, {3, 4}}, {{5, 6}, {7, 8}}] // MatrixForm

or

Inner[Composition[HoldForm, Times], {{1, 2}, {3, 4}}, {{5, 6}, {7, 8}}] // MatrixForm

to get

Answer 3

The previous answers all use Inner to perform the specific operation of Dot, but these do not provide a general way to visualize results. I cannot provide a truly general way either but I feel that this has wider application:

SetAttributes[show, HoldFirst]
form[expr_] := expr /. m_ /; MatrixQ@Unevaluated@m :> MatrixForm[m]
show[expr_] :=
  Row[{Defer[expr], Unevaluated[expr] /. n_?NumericQ :> Defer[n], expr}, "="] // form

Test:

{{1, 2}, {3, 4}}.{{5, 6}, {7, 8}} // show

In the simpler example a possible problem appears:

{1, 1} + {1, -1} // show

This is because of the behavior:

"foo" + "foo" + "foo"

3 "foo"

If this is unacceptable I shall have to include special handling.

Note: be aware of the automatic formatting that is applied even to held expressions; see:

• Returning an unevaluated expression with values substituted in

Answer 4

This is not an answer, but, based on chuy's solution, I want to show one of the advantages of the new V10 Inactive:

(x = Inner[Inactive[Times],
    {{1, 2}, {3, 4}}, {{5, 6}, {7, 8}},
       Inactive[Plus]]) // MatrixForm

Activate[x, Times] // MatrixForm

Activate[x] // MatrixForm

Answer 5

Inspired by @Mr.Wizard's answer. This should work with both numbers and symbols:

ClearAll[elementDisplay]
SetAttributes[elementDisplay, HoldAll]
elementDisplay[f_[arg__List]] := f @@ Function[x, Defer[x], Listable]@{arg} // MatrixForm
elementDisplay[{{1, 2}, {a, b}}.{{5, 6}, {c, d}}]

ClearAll[listOpDisplay]
SetAttributes[listOpDisplay, HoldAll]
listOpDisplay[f_[arg__List]] := 
 Row[{Defer[f[arg]], f @@ Function[x, Defer[x], Listable]@{arg}, 
    f[arg]}, "="] /.
  m_ /; MatrixQ@Unevaluated@m :> MatrixForm@m

listOpDisplay[{{1, 2}, {3, 4}}.{{5, 6}, {7, 8}}]

listOpDisplay[Cross[{1, 2, 3}, {1, 1/2, 1/3}]]