How can I find the value of this integral?
Integrate[E^((-b)*t^a - k*t), {t, 0, Infinity}]
$\begingroup$
$\endgroup$
4
3 Answers
$\begingroup$
$\endgroup$
2
General formula exist. Can be expressed by FoxH function:
Integrate[Exp[-k*t - b*t^a], {t, 0, Infinity}] == (b^(-1/a) FoxH[{{{1 - 1/a, 1/a}}, {}}, {{{0, 1}}, {}}, b^(-1/a) k])/a
Mathematica can't compute this kind integrals because is not Updated.
FoxH function was introduced in 2021 year in version 12.1.
During this time, nothing happened for Mathematica to calculate such integrals.
$Version
(* "13.3.0 for Microsoft Windows (64-bit) (June 3, 2023)"*)
FHI[k_, b_, a_] := NIntegrate[Exp[-k*t - b*t^a], {t, 0, Infinity}]
FHI[1, 2, 4/3]
(* 0.377357 *)
FHA[k_, b_, a_] := (b^(-1/a) FoxH[{{{1 - 1/a, 1/a}}, {}}, {{{0, 1}}, {}}, b^(-1/a) k])/a
FHA[1, 2, 4/3]
(*(3 FoxH[{{{1/4, 3/4}}, {}}, {{{0, 1}}, {}}, 1/2^(3/4)])/(4 2^(3/4))*)
% // FunctionExpand
(*(3 (3/2)^(1/4)*Gamma[7/12] Gamma[11/
12] HypergeometricPFQ[{7/12, 11/12}, {1/2, 3/4}, 27/2048])/(
8 Gamma[3/4]) -
3/16 Sqrt[\[Pi]/2]
HypergeometricPFQ[{5/6, 7/6}, {3/4, 5/4}, 27/2048] + (
9 (3/2)^(3/4)
Gamma[13/12] Gamma[17/
12] HypergeometricPFQ[{13/12, 17/12}, {5/4, 3/2}, 27/2048])/(
128 Gamma[5/4]) -
1/32 HypergeometricPFQ[{1, 4/3, 5/3}, {5/4, 3/2, 7/4}, 27/2048]*)
% // N
(* 0.377357 *)
Generalization for more exotic integral:
Integrate[x^a1*Exp[-a2*x^a3 - a4*x^a5], {x, 0, Infinity}] == (a4^(-((1 + a1)/a5))*FoxH[{{{1 - (1 + a1)/a5, a3/a5}}, {}}, {{{0, 1}}, {}}, a2 a4^(-(a3/a5))])/a5
EDIT:
This kind integrals is easy to compute using Mellin Transform and Inverse Mellin Transform:
inv = InverseMellinTransform[Integrate[
MellinTransform[Exp[-k*t - b*t^a], b, s], {t, 0, Infinity},
Assumptions -> {k > 0, a > 0}][[1]], s, b](*Can't Compute.Weakness!*)
(* InverseMellinTransform[k^(-1 + a s) Gamma[s] Gamma[1 - a s], s, b] *)
From defintion of FoxH function we can easy establish formula by a Mellin–Barnes integral (Inverse Mellin Transform)
1/(2 Pi I) ContourIntegrate[k^(-1 + a s) Gamma[s] Gamma[1 - a s]*b^-s /. k -> 1 /. b -> 2/. a -> 4/3, s \[Element] InfiniteLine[{1/3, 0}, {0, 1}]](*Can't Compute.Weakness!*)
1/(2 Pi I) NContourIntegrate[k^(-1 + a s) Gamma[s] Gamma[1 - a s]*b^-s /. k -> 1 /. b -> 2 /. a -> 4/3, s \[Element] InfiniteLine[{1/3, 0}, {0, 1}]]
(* 0.377357 + 0. I *)
answered Jun 29 at 8:38
-
$\begingroup$ Good to know general formula exists. But how did you get it? Are you using V 14.1 may be? In V 14 it returns unevaluated. screen shot i.sstatic.net/3xQxWNlD.png $\endgroup$– NasserCommented Jun 29 at 8:46
-
$\begingroup$ @Nasser. I have many such integrals because I once calculated them, the result of which is the FoxH function. I only have ready results and no way to calculate them. Maybe soon I will show you how to calculate such an integral. $\endgroup$ Commented Jun 29 at 8:59
$\begingroup$
$\endgroup$
Probably no closed formula for this integral is known for general value of a. As commented by @mikado, you can get a (complicated) formula if a is a rational number. For example,
Assuming[b > 0 && a == 4/3,
Integrate[Exp[-b t^a - k t], {t, 0, Infinity}]]
$\begingroup$
$\endgroup$
This also shows that for different values of $a$, solutions can be very different. So general formula is most likely do not exist.
Mathematica also hangs on some specific values of $a$. So I put time constrained of 30 seconds.
This is all for 1<=a<=2 range
e = Exp[-b*t^a-k*t];
data = Table[{n,TimeConstrained[Simplify@Integrate[e/.a->n,{t,0,Infinity},
Assumptions->{k>0,b>0}],30]},{n,1,2,1/10}];
title = {"a","result"};
Grid[Prepend[data,title],Frame->All]
gives this (click to enlarge). Only for $a=1,a=2$ is the result very simple. For some values of $a$ it aborts time given, else it might hang or take very long time.
I also tried Rubi for the indefinite version and it can't solve it.
a, you can get a complicated answer (typically involvingHypergeometricPFQ) $\endgroup$