# Distributive property of Integration

As it is known that Integrate[A+B]= Integrate[A] + Integrate[B]

I am facing problem with the following integral, when I integrate

Integrate[(-(1/2) b^2 x^2 (-1 + EulerGamma + Log[(b x)/2]) -
2 (EulerGamma + Log[(b x)/2])) 1/
x ((-1 + x) Log[-1 + x]^2 - 2 (-1 + x) Log[-1 + x] (1 + Log[x]) +
2 x Log[x] (2 + Log[x]) -
2 (1 + x) (1 + Log[x]) Log[1 + x] + (1 + x) Log[1 + x]^2) , {x,
1, \[Infinity]}]


I obtain an answer but when I wish to solve a part

Integrate[-(1/2) b^2 x^2 (-1 + EulerGamma + Log[(b x)/2]) 1/
x ((-1 + x) Log[-1 + x]^2 - 2 (-1 + x) Log[-1 + x] (1 + Log[x]) +
2 x Log[x] (2 + Log[x]) -
2 (1 + x) (1 + Log[x]) Log[1 + x] + (1 + x) Log[1 + x]^2) , {x,
1, \[Infinity]}]


Mathematica 11 do not returns any value and processing goes on.

• I too have encountered this issue. I suspect that the full integration admits some cancellation of terms that the individual portions do not. Commented Sep 17, 2021 at 17:35
• With v12.3.1 your first integral returns unevaluated. Commented Sep 17, 2021 at 20:26

Don't know why the definite integral of the part integral does not work, but with indefinite integration you get the right result (in MMA version 8.0)

f[x_, b_] =
(-(1/2) b^2 x^2 (-1 + EulerGamma + Log[(b x)/2]) -
2 (EulerGamma + Log[(b x)/2])) 1/
x ((-1 + x) Log[-1 + x]^2 - 2 (-1 + x) Log[-1 + x] (1 + Log[x]) +
2 x Log[x] (2 + Log[x]) -
2 (1 + x) (1 + Log[x]) Log[1 + x] + (1 + x) Log[1 + x]^2);

g[x_, b_] =
-(1/2) b^2 x^2 (-1 + EulerGamma + Log[(b x)/2]) 1/
x ((-1 + x) Log[-1 + x]^2 - 2 (-1 + x) Log[-1 + x] (1 + Log[x]) +
2 x Log[x] (2 + Log[x]) -
2 (1 + x) (1 + Log[x]) Log[1 + x] + (1 + x) Log[1 + x]^2);

h[x_, b_] =
1/x (-2 (EulerGamma + Log[(b x)/2])) ((-1 + x) Log[-1 + x]^2 -
2 (-1 + x) Log[-1 + x] (1 + Log[x]) + 2 x Log[x] (2 + Log[x]) -
2 (1 + x) (1 + Log[x]) Log[1 + x] + (1 + x) Log[1 + x]^2);

f[x, b] - g[x, b] - h[x, b] // Simplify

(*   0   *)


.

intf[b_] = Integrate[f[x, b], {x, 1, \[Infinity]}]

(*   (17 \[Pi]^4)/180 - 8 EulerGamma Log[2] + 4 Log[2]^2 +
4 EulerGamma Log[2]^2 + 1/3 \[Pi]^2 Log[2]^2 - 4 Log[2]^3 -
Log[2]^4/3 + Log[256] - 8 PolyLog[4, 1/2] - (7 Zeta[3])/2 +
7/2 EulerGamma Zeta[3] - 21/2 Log[2] Zeta[3] +
1/144 b^2 (\[Pi]^2 (-5 + 6 EulerGamma - 6 Log[2]) - 8 Log[2] +
48 EulerGamma (-1 + Log[2]) Log[2] - 16 Log[2]^2 - 48 Log[2]^3 +
63 Zeta[3]) +
1/24 Log[b] (b^2 (\[Pi]^2 + 8 (-1 + Log[2]) Log[2]) +
12 (-16 Log[2] + 8 Log[2]^2 + 7 Zeta[3]))   *)


.

iintg = Integrate[g[x, b], x]

(*   -(1/1296)b^2 (169 - 216 EulerGamma - 27 Log[4] + 396 Log[1 - x] -
396 EulerGamma Log[1 - x] + 216 Log[-1 + x] +
180 EulerGamma Log[-1 + x] - 612 x Log[-1 + x] +
216 EulerGamma x Log[-1 + x] - 576 x^2 Log[-1 + x] +
432 EulerGamma x^2 Log[-1 + x] + 576 x^3 Log[-1 + x] -
432 EulerGamma x^3 Log[-1 + x] - 48 Log[8] Log[-1 + x] -
198 Log[-1 + x]^2 + 108 EulerGamma Log[-1 + x]^2 +
486 x^2 Log[-1 + x]^2 - 324 EulerGamma x^2 Log[-1 + x]^2 -
288 x^3 Log[-1 + x]^2 + 216 EulerGamma x^3 Log[-1 + x]^2 -
216 Log[x] + 1224 x Log[x] - 432 EulerGamma x Log[x] -
1152 x^3 Log[x] + 864 EulerGamma x^3 Log[x] +
36 Log[1 - x] Log[x] - 216 EulerGamma Log[1 - x] Log[x] +
360 Log[-1 + x] Log[x] - 972 x^2 Log[-1 + x] Log[x] +
648 EulerGamma x^2 Log[-1 + x] Log[x] +
576 x^3 Log[-1 + x] Log[x] -
432 EulerGamma x^3 Log[-1 + x] Log[x] -
108 Log[-1 + x]^2 Log[x] - 576 x^3 Log[x]^2 +
432 EulerGamma x^3 Log[x]^2 + 216 Log[(b x)/2] +
144 Log[1 - x] Log[(b x)/2] - 504 Log[-1 + x] Log[(b x)/2] +
216 x Log[-1 + x] Log[(b x)/2] +
432 x^2 Log[-1 + x] Log[(b x)/2] -
432 x^3 Log[-1 + x] Log[(b x)/2] +
108 Log[-1 + x]^2 Log[(b x)/2] -
324 x^2 Log[-1 + x]^2 Log[(b x)/2] +
216 x^3 Log[-1 + x]^2 Log[(b x)/2] - 432 x Log[x] Log[(b x)/2] +
864 x^3 Log[x] Log[(b x)/2] -
216 Log[1 - x] Log[x] Log[(b x)/2] +
648 x^2 Log[-1 + x] Log[x] Log[(b x)/2] -
432 x^3 Log[-1 + x] Log[x] Log[(b x)/2] +
432 x^3 Log[x]^2 Log[(b x)/2] + 144 Log[-1 + x] Log[b x] -
888 Log[1 + x] + 396 EulerGamma Log[1 + x] - 612 x Log[1 + x] +
216 EulerGamma x Log[1 + x] + 576 x^2 Log[1 + x] -
432 EulerGamma x^2 Log[1 + x] + 576 x^3 Log[1 + x] -
432 EulerGamma x^3 Log[1 + x] - 216 Log[x] Log[1 + x] +
216 EulerGamma Log[x] Log[1 + x] + 972 x^2 Log[x] Log[1 + x] -
648 EulerGamma x^2 Log[x] Log[1 + x] +
576 x^3 Log[x] Log[1 + x] -
432 EulerGamma x^3 Log[x] Log[1 + x] +
36 Log[(b x)/2] Log[1 + x] + 216 x Log[(b x)/2] Log[1 + x] -
432 x^2 Log[(b x)/2] Log[1 + x] -
432 x^3 Log[(b x)/2] Log[1 + x] +
216 Log[x] Log[(b x)/2] Log[1 + x] -
648 x^2 Log[x] Log[(b x)/2] Log[1 + x] -
432 x^3 Log[x] Log[(b x)/2] Log[1 + x] + 198 Log[1 + x]^2 -
108 EulerGamma Log[1 + x]^2 - 486 x^2 Log[1 + x]^2 +
324 EulerGamma x^2 Log[1 + x]^2 - 288 x^3 Log[1 + x]^2 +
216 EulerGamma x^3 Log[1 + x]^2 + 108 Log[-x] Log[1 + x]^2 -
108 Log[(b x)/2] Log[1 + x]^2 +
324 x^2 Log[(b x)/2] Log[1 + x]^2 +
216 x^3 Log[(b x)/2] Log[1 + x]^2 + 324 Log[2 (1 + x)] -
324 EulerGamma Log[2 (1 + x)] - 324 Log[x] Log[2 (1 + x)] +
324 Log[(b x)/2] Log[2 (1 + x)] - 48 Log[3 (1 + x)] +
144 EulerGamma Log[3 (1 + x)] + 144 Log[x] Log[3 (1 + x)] -
144 Log[(b x)/2] Log[3 (1 + x)] -
216 Log[-1 + x] PolyLog[2, 1 - x] +
36 (-5 + 6 EulerGamma + 6 Log[x] + 6 Log[(b x)/2]) PolyLog[
2, -x] + 180 PolyLog[2, x] - 216 EulerGamma PolyLog[2, x] -
216 Log[x] PolyLog[2, x] - 216 Log[(b x)/2] PolyLog[2, x] +
216 Log[1 + x] PolyLog[2, 1 + x] + 216 PolyLog[3, 1 - x] -
432 PolyLog[3, -x] + 432 PolyLog[3, x] - 216 PolyLog[3, 1 + x])   *)

limo = Limit[iintg, x -> \[Infinity]]

(*   1/1296 b^2 (-169 - 396 I \[Pi] - 90 \[Pi]^2 - 54 Log[2] -
108 \[Pi]^2 Log[2] + 324 Log[2]^2 + 48 Log[3] -
144 Log[2] Log[3] +
36 EulerGamma (6 + 11 I \[Pi] + 3 \[Pi]^2 + Log[512/81]) +
36 I \[Pi] Log[16] +
36 (-6 - 4 I \[Pi] + 3 \[Pi]^2 - 9 Log[2] + Log[81]) Log[b])   *)

limu = Limit[iintg, x -> 1, Direction -> -1]

(*   1/1296 b^2 (-169 - 396 I \[Pi] - 36 Log[2] - 36 I \[Pi] Log[2] +
468 Log[2]^2 - 324 I \[Pi] Log[2]^2 + 432 Log[2]^3 + 48 Log[3] -
144 Log[2] Log[3] + 27 Log[4] - 180 PolyLog[2, 2] -
432 Log[2] PolyLog[2, 2] +
36 Log[b] (-6 - 12 Log[2]^2 + I \[Pi] (-4 + Log[64]) + Log[648] +
6 PolyLog[2, 2]) +
36 EulerGamma (6 - 12 Log[2]^2 + I \[Pi] (11 + Log[64]) +
Log[2097152/81] + 6 PolyLog[2, 2]) + 216 PolyLog[3, 2] -
756 Zeta[3])   *)

intg[b_] = limo - limu // FullSimplify

(*   -(1/144) b^2 (16 Log[
2] (3 EulerGamma + Log[2] - EulerGamma Log[8] +
Log[2] Log[8]) + \[Pi]^2 (5 - 6 EulerGamma + Log[64]) +
Log[256] - 6 (\[Pi]^2 + 8 (-1 + Log[2]) Log[2]) Log[b] -
63 Zeta[3])   *)


.

inth[b_] = Integrate[h[x, b], {x, 1, \[Infinity]}]

(*   -2 (-((17 \[Pi]^4)/360) - 4 Log[2] - 2 Log[2]^2 -
2 EulerGamma Log[2]^2 - 1/6 \[Pi]^2 Log[2]^2 + 2 Log[2]^3 +
Log[2]^4/6 + EulerGamma Log[16] - 2 (-2 + Log[2]) Log[2] Log[b] +
4 PolyLog[4, 1/2] - 7/4 (-1 + EulerGamma + Log[b/8]) Zeta[3])   *)

intf[b] - intg[b] - inth[b] // FullSimplify

(*   0   *)


The distributive property only holds when both integrals are convergent. For example:

Integrate[Exp[-x] + Pi/(2x) - ArcTan[x]/x, {x, 1, Infinity}]


Catalan + 1/E

However:

Integrate[Exp[-x] + Pi/(2x), {x, 1, Infinity}]
Integrate[ - ArcTan[x]/x, {x, 1, Infinity}]


Integrate::idiv: Integral of E^-x+[Pi]/(2 x) does not converge on {1,[Infinity]}.

Integrate[E^(-x) + Pi/(2*x), {x, 1, Infinity}]

Integrate::idiv: Integral of -(ArcTan[x]/x) does not converge on {1,[Infinity]}.

Integrate[-(ArcTan[x]/x), {x, 1, Infinity}]

The same thing is happening for your example.

• But if Integrate(A) and Integrate(A+B) both are convergent then Intgerate(B) must converge. Commented Sep 17, 2021 at 18:39