How to obtain non-trivial solution?

Question

I have the following system of equations.

$ quad\quad\quad\quad u+\alpha v+v+e^{\frac{i \alpha }{2}} (\alpha -1) x=\alpha u+e^{-\frac{1}{2} (i \alpha )} (\alpha +1) z, +u+v=\alpha (v+w)+w+y, (\alpha -1) e^{\frac{i \alpha }{2}} (\alpha +1) x=(\alpha +1) y$

How can I obtain a non-trivial solution of this system?

Answer 1

Mathematica is correct. In general, there will only be the trivial solution.

You are trying so solve an equation $ M x = b $ with $ b= 0$. This will have a nontrivial solution if and only if $\mathrm{det} M = 0$, because otherwise the matrix can be inverted, i.e. there exists a matrix $M^{-1}$ such that $M M^{-1} = M^{-1} M = I$, where $I$ is the identity matrix.

For linear systems there is a function LinearSolve[m, b] which takes a matrix m and the "right-hand side" vector b as arguments.

You can convert your list of equations to a linear system (matrix + vector) as follows.

eqs = {
   E^(-(1/2) I (\[Alpha] + 
          2 \[Pi] \[Alpha])) ((-E^(I (2 \[Alpha] + \[Theta])) w + 
          E^(1/2 I (3 + 4 \[Pi]) \[Alpha]) z) (-1 + \[Alpha]) - 
       E^(1/2 I (\[Alpha] + 4 \[Pi] \[Alpha])) x (1 + \[Alpha]) + 
       E^(I (4 \[Pi] \[Alpha] + \[Theta])) y (1 + \[Alpha])) == 0,
   E^(-I (\[Alpha] + \[Pi] \[Alpha] - \[Theta])) (-E^(2 I \[Pi] \
\[Alpha]) v (-1 + \[Alpha]) + 
       E^(4 I \[Pi] \[Alpha]) y (-1 + \[Alpha]) + 
       E^(2 I (1 + \[Pi]) \[Alpha]) u (1 + \[Alpha]) - 
       E^(2 I \[Alpha]) w (1 + \[Alpha])) == 0,
   E^(-I \[Alpha]) (-E^(((I \[Alpha])/2)) x (-1 + \[Alpha]) + 
       E^((3 I \[Alpha])/2) z (1 + \[Alpha]) + 
       E^(I \[Theta]) (E^(2 I \[Alpha]) u (-1 + \[Alpha]) - 
          v (1 + \[Alpha]))) == 0,
   u + v + E^((I \[Alpha])/2) x (-1 + \[Alpha]) + v \[Alpha] == 
    u \[Alpha] + E^(-((I \[Alpha])/2)) z (1 + \[Alpha]),
   u + v + (u + y) \[Alpha] == w + y + (v + w) \[Alpha],
   (w - E^(-((I \[Alpha])/2)) z) (-1 + \[Alpha]) + 
     E^((I \[Alpha])/2) x (1 + \[Alpha]) == y (1 + \[Alpha])
 };
(* Convert to expressions *)
exprs = eqs /. Equal[a_, b_] :> a - b

vars = {x, y, z, w, u, v}
(* Extract coefficients as matrix *)
m = Function[{x}, Map[Coefficient[x, #, 1] &, vars]] /@ exprs;
(* Extract right-hand side vector (note the minus). *)
b = - exprs /. (# -> 0 & /@ vars);

You can then check that Det[m] is in general nonzero and therefore the solution of the linear system is trivial.

Edit: However, there are instances in which the system is singular and there exists therefore a family of solutions to the equation $M x =0$.

As I said, in general the determinant Det[m] is nonzero. Therefore one needs to find values of the parameters \[Alpha] and \[Theta] such that the determinant vanishes. (There might be others.)

inst = First@FindInstance[Det[m] == 0, {\[Alpha], \[Theta]}]
(* {\[Alpha] -> 0, \[Theta] -> 0 *)

Then you can find a solution

FindInstance[m.vars == b && vars != 0 /. inst, vars]
(* {{x -> 0, y -> -1, z -> -1, w -> 0, u -> 1, v -> -2}} *)