How to obtain non-zero solution of the given system of equations?

Question

I have this system of six equations for $\{x,y,z,u,w,v\}$.

sixeqs = {I (-x + v) + u == (α x)/2 + y    , 
   z + I  (w + v) == u    , 
   1/2 (-2 I + α) x + y + I w ==  z, 
(2 I + α) x +  2 E^(-I (2 β π - β γ +  t)) ((2 π- I - γ) w + z) == 2 y    ,   
 E^(-I (β (π - γ) + t)) ((-2 π - I + γ) w - z +  E^(2 I β π) ((-I + γ) v + u)) ==  0,
 (I - α/2) x + y == E^(I (β γ - t)) ((I + γ) v + u)  };

I want to find a non-zero solution for $\{x,y,z,u,w,v\}$ if it exists; I use Solve and the assumptions I have, but it gives only the trivial solution $\{x,y,z,u,w,v\}=\{0,0,0,0,0,0\}$.

Assuming[{    α > 0 &&α ∈   Reals  &&  γ> 0 &&  γ ∈ Reals   && t ∈ Reals && β ∈ Reals     }, 
 Simplify[ Solve[ sys, {x, y, z, w, u, v}]]]
(*{{x -> 0, y -> 0, z -> 0, w -> 0, u -> 0, v -> 0}}*)

Then, when I replace Solve with Reduce, it takes a lot of running time.

My question:

How can I obtain nonzero solutions for $\{x,y,z,u,v,w\}$?

Answer 1

Your six equations seem to be linear and homogenous M.{x, y, z, u, v, w}==0:

eqn = sixeqs /. Equal -> Subtract;
M = D[eqn, {{x, y, z, u, v, w}}];
M . {x, y, z, u, v, w} == eqn // Simplify(*True*)

Condition for nontrivial solution is Det[M]==0

tmp=Simplify[Det[M], {\[Alpha] > 0 && \[Alpha] \[Element] Reals && \[Gamma] >0 && \[Gamma] \[Element] Reals && t \[Element] Reals && \[Beta] \[Element] Reals}] 

    (*8 E^(-I (3 t + 3 \[Pi] \[Beta] - \[Beta] \[Gamma])) (E^(
    I (t + \[Beta] \[Gamma])) (-2 I + \[Alpha]) + 
   E^(I (t + \[Beta] (4 \[Pi] + \[Gamma]))) (2 I + \[Alpha]) - 
   2 E^(I (t + \[Beta] (2 \[Pi] + \[Gamma]))) (2 \[Pi] + \[Alpha]) + 
   E^(2 I \[Beta] (\[Pi] + \[Gamma])) (-2 I + 2 \[Pi] - \[Gamma]) + 
   E^(2 I (t + \[Pi] \[Beta])) (2 I + 2 \[Pi] - \[Gamma]) + 
   E^(2 I (t + 2 \[Pi] \[Beta])) (-2 I + \[Gamma]) + 
   E^(2 I \[Beta] \[Gamma]) (2 I + \[Gamma])) *)
   

Addendum*

Using this condition the nontrivial solution follows:

cond = Solve[tmp == 0, \[Alpha]][[1]];
sol=Solve[(M /. cond) . {x, y, z, u, v, w} == 0, {x, y, z, w, u,v}];
Simplify[%, {\[Alpha] > 0 && \[Alpha] \[Element] Reals && \[Gamma] >0 && \[Gamma] \[Element] Reals && t \[Element] Reals && \[Beta] \[Element] Reals}] 

    (*{{y -> (1/(2 (-1 + E^(2 I \[Pi] \[Beta]))^2))
   E^(-I (t + \[Beta] \[Gamma]))
     x (E^(2 I \[Beta] (\[Pi] + \[Gamma])) (-2 I + 
         2 \[Pi] - \[Gamma]) - 
      E^(2 I (t + 2 \[Pi] \[Beta])) (-2 I + \[Gamma]) + 
      E^(2 I \[Beta] \[Gamma]) (2 I + \[Gamma]) + 
      E^(2 I (t + \[Pi] \[Beta])) (-2 I - 2 \[Pi] + \[Gamma])), 
  z -> (1/((-1 + E^(2 I \[Pi] \[Beta]))^2))
   E^(I \[Beta] (2 \[Pi] - \[Gamma]))
     x (-I E^(I \[Beta] (2 \[Pi] + \[Gamma])) + 
      E^(I \[Beta] \[Gamma]) (I + 2 \[Pi]) - 
      E^(I (t + 2 \[Pi] \[Beta])) (-I + \[Gamma]) + 
      E^(I t) (-I - 2 \[Pi] + \[Gamma])), 
  w -> (E^(2 I \[Pi] \[Beta]) (1 - E^(
      I (t - \[Beta] \[Gamma]))) x)/(-1 + E^(2 I \[Pi] \[Beta])), 
  u -> (1/((-1 + E^(2 I \[Pi] \[Beta]))^2))
   E^(-I \[Beta] \[Gamma])
     x (I E^(I \[Beta] \[Gamma]) + 
      E^(I \[Beta] (2 \[Pi] + \[Gamma])) (-I + 2 \[Pi]) - 
      E^(I (t + 4 \[Pi] \[Beta])) (-I + \[Gamma]) + 
      E^(I (t + 2 \[Pi] \[Beta])) (-I - 2 \[Pi] + \[Gamma])), 
  v -> (x - E^(I (t + 2 \[Pi] \[Beta] - \[Beta] \[Gamma])) x)/(
   1 - E^(2 I \[Pi] \[Beta]))}}*)