How to solve this seemingly simple system of algebraic equations?

Question

I mean $$ \text{z1}+\text{z2}+\text{z3}+\text{z4}=0\land | \text{z1}| =| \text{z2}| \land | \text{z3}| =| \text{z2}| \land | \text{z3}| =| \text{z4}|$$ in $\text{z1},\text{z2},\text{z3},\text{z4}$ over the complexes.

Here are my unsuccessful trials in 13.2 on Windows 10.

(i)

Solve[z1 + z2 + z3 + z4 == 0 && Abs[z1] == Abs[z2] && Abs[z3] == Abs[z2] && Abs[z3] == Abs[z4], 
{z1, z2, z3,z4}, Complexes]

Solve::ifun: Inverse functions are being used by Solve, so some solutions may not be found; use Reduce for complete solution information.

Solve::svars: Equations may not give solutions for all "solve" variables.

{{z2->z1,z3->-z1,z4->-z1},{z2->-z1,z3->z1,z4->-z1},{z2->-z1,z3->-z1,z4->z1},{z1->0,z2->0,z3->0,z4->0}}

Most of the solutions are lost.

(ii) The command

Reduce[z1 + z2 + z3 + z4 == 0 && Abs[z1] == Abs[z2] && Abs[z3] == Abs[z2] && 
Abs[z3] == Abs[z4], {z1, z2, z3, z4}, Complexes]

almost crashes my comp: "Kernel connection is lost".

(iii)

With the additional constraint Abs[z1]==1,

Solve[z1 + z2 + z3 + z4 == 0 && Abs[z1] == Abs[z2] && Abs[z3] == Abs[z2] && 
Abs[z3] == Abs[z4] && Abs[z1] == 1, {z1, z2, z3, z4}, Complexes]

Solve::ifun: Inverse functions are being used by Solve, so some solutions may not be found; use Reduce for complete solution information.

{{z1 -> 1, z2 -> 1, z3 -> -1, z4 -> -1}, {z1 -> 1, z2 -> -1, z3 -> 1, z4 -> -1}, {z1 -> -1, z2 -> 1, z3 -> 1, z4 -> -1}, {z1 -> 1, z2 -> -1, z3 -> -1, z4 -> 1}, {z1 -> -1, z2 -> 1, z3 -> -1, z4 -> 1}, {z1 -> -1, z2 -> -1, z3 -> 1, z4 -> 1}}

Most of the solutions are lost.

(iv)

Reduce[z1 + z2 + z3 + z4 == 0 && Abs[z1] == Abs[z2] &&  Abs[z3] == Abs[z2] &&
Abs[z3] == Abs[z4] && Abs[z1] == 1, {z1, z2, z3, z4}, Complexes]

is running without any response on my comp for hours. The resources of my comp are not exhausted. Likely an infinite loop is formed.

(v) The switching to the reals by

Reduce[x1 + x2 + x3 + x4 == 0 && y1 + y2 + y3 + y4 == 0 && 
x1^2 + y1^2 == x2^2 + y2^2 && x3^2 + y3^2 == x2^2 + y2^2 && 
x3^2 + y3^2 == x4^2 + y4^2 && x1^2 + y1^2 == 1, {x1, x2, x3, x4, y1,y2, y3, y4},Reals]

does not help. The command is running without any response on my comp for hours. The resources of my comp are not exhausted. Likely an infinite loop is created.

Answer 1

By taking z1==1, you can find a solution set that you can scale by any complex constant.

Decomposing into real and imaginary components I have

eqn = 1 + c1 + c2 + c3 == 0 && s1 + s2 + s3 == 0 && c1^2 + s1^2 == c2^2 + s2^2 == c3^2 + s3^2 == 1;

This can be solved easily using

Reduce[eqn, Reals]

Alternatively, you find a few interesting values, e.g.

FindInstance[1 + c1 + c2 + c3 == 0 && s1 + s2 + s3 == 0 && 
c1^2 + s1^2 == c2^2 + s2^2 == c3^2 + s3^2 == 1, {c1, c2, c3, s1, s2, s3}, Reals, 8]