How to align dynamic graphics and an image within an Overlay?

Question

I have dynamic graphics over an image but they won't line up, what am I doing wrong?

img = ExampleData[ExampleData["TestImage"][[1]]];
d = ImageDimensions@img;
pt1=d/4;pt2={d[[1]]3/4,d[[2]]1/4};pt3=3d/4;pt4={d[[1]]1/4,d[[2]]3/4};

MultiContourPolygon[polys_List] := Module[{contours = Append[#, First[#]]&/@polys}, 
    {Polygon@Join[Join@@contours,Reverse[First/@contours]],Line[contours]}
]

LocatorPane[
    Dynamic[{pt1,pt2,pt3,pt4}],
    Overlay[{img,
        Graphics[{Orange, Opacity[.4], 
            Dynamic @ MultiContourPolygon[{{pt1,pt2,pt3,pt4}, {{0,0}, {d[[1]],0},d,{0,d[[2]]}}}]},
            ImagePadding -> 0, ImageMargins -> 0, ImageSize -> d
        ]
        }, Alignment -> {Left,Bottom}, ImageSize -> d
    ]
]

Answer 1

You need to specify the Plot Range:

LocatorPane[Dynamic[{pt1, pt2, pt3, pt4}], 
 Overlay[{Image[img, ImageSize -> 400], 
   Graphics[{Orange, Opacity[.4], 
     Dynamic@MultiContourPolygon[{{pt1, pt2, pt3, 
         pt4}, {{0, 0}, {d[[1]], 0}, d, {0, d[[2]]}}}]}, 
    ImagePadding -> 0, ImageSize -> 400, 
    PlotRange -> Transpose[{{0, 0}, d}]]}, Alignment -> {Left, Left}, 
  ImageSize -> 400]]

Answer 2

Another way to do that is to use Show:

LocatorPane[Dynamic[{pt1, pt2, pt3, pt4}], 
 Show[Image[img], 
  Graphics[{Orange, Opacity[.4], 
    Dynamic@MultiContourPolygon[{{pt1, pt2, pt3, 
        pt4}, {{0, 0}, {d[[1]], 0}, d, {0, d[[2]]}}}]}, 
   ImagePadding -> 0]]]

With this solution you do not have to specify any PlotRange or ImageSize.

Answer 3

This is related to this recent question: relative scale of elements in ImageCompose

My answer is similar:

LocatorPane[Dynamic[{pt1, pt2, pt3, pt4}],
 Show[
  Rasterize @ img,
  Epilog ->
   {Orange, Opacity[.4], 
    Dynamic@MultiContourPolygon[{{pt1, pt2, pt3, pt4}, {{0, 0}, {d[[1]], 0}, 
        d, {0, d[[2]]}}}]}
 ]
]

This way there is no need to mess with ImagePadding, ImageMargins, ImageSize, Alignment, PlotRange or any such options.