How to find the limit of a function of two variables

Question

I was wondering if there is a method to find the limit of a function of two variables at a point. I tried the following:

Limit[(x^4 + y^2)/(x^2 + y^2), (x, y) -> (0, 0)]

Limit[(x^4 + y^2)/(x^2 + y^2), x -> 0, y -> 0]

but neither of them worked,

Answer 1

As already mentioned in a comment this limit does not exist without saying more about the way you'd like to approach the point {0,0}.

First of all, I shall take the y^2 in the numerator seriously and not as mistyped y^4.

The 3D plot already shows the problem: in the vicinity of {0,0} the function is not continuous

Plot3D[f, {x, -1, 1}, {y, -1, 1}]

In the comment it was suggested to walk on the line y = mx but there are many other possibilities some of which will be shown here.

1) In polar coordinates (which is just another formulation of y = m*x) we have

fp = (x^4 + y^2)/(x^2 + y^2) /. {x -> r Cos[\[Phi]], y -> r Sin[\[Phi]]} // 
  Simplify

(* Out[129]= r^2 Cos[\[Phi]]^4 + Sin[\[Phi]]^2 *)

And the limit r->0 gives

Limit[fp, r -> 0]

(* Out[130]= Sin[\[Phi]]^2 *)

Which is any real number between 0 and 1, depending on [Phi].

2) Now taking a logarithmic spiral

fs = fp /. \[Phi] -> -Log[r]

(* Out[186]= r^2 Cos[Log[r]]^4 + Sin[Log[r]]^2 *)

Limit[%, r -> 0]

(* Out[187]= Interval[{0, 1}] *)

and we get any number between 0 and 1.

You can also plot fs. Notice that the picture is more or less scale invariant wth respect to the choice of the upper limit of the plotting interval

Plot[fs, {r, 0, 1/100}] (* not shown here *)

3) We can also take a discrete sequence

Let the path be given by the points {xn,yn} where

xn = 1/FindSequenceFunction[{1, 2, 2, 4, 4, 8, 8, 16, 16}, n]

(*
Out[256]= -(2^(2 - n/2)/(-2 - 2 (-1)^n - Sqrt[2] + (-1)^n Sqrt[2]))
*) 

yn = 1/FindSequenceFunction[{1, 1, 2, 2, 4, 4, 8, 8, 16, 16}, n]

(*
Out[257]= -(2^(2 - n/2)/(-1 + (-1)^(1 + n) - Sqrt[2] + (-1)^n Sqrt[2]))
*)

The beginning of the sequence is then

s = Table[{xn, yn}, {n, 1, 10}]

(*
Out[258]= {{1, 1}, {1/2, 1}, {1/2, 1/2}, {1/4, 1/2}, {1/4, 1/4}, {1/8, 1/4}, {1/8, 1/8}, {1/16, 1/8}, {1/16, 1/16}, {1/32, 1/16}}
*)

Here is the beginning of the path

Show[Graphics[{{Blue, Line[{{0, 0}, {1.1, 0}, {1.1, 1.1}, {0, 1.1}, {0, 0}}]},
    Line@s}]]

Our function becomes

fs = f /. {x -> xn, y -> yn};

The plot is

ListPlot[Table[fs, {n, 1, 20}], PlotRange -> {0, 1.1}]

Closer inspection of fs starts with

FullSimplify[fs, {n > 0, n \[Element] Integers}] // Expand

(*
Out[300]= 5/(7 + 3 (-1)^n) + (3 (-1)^n)/(7 + 3 (-1)^n) + (3 2^-n)/(
 7 + 3 (-1)^n) + ((-1)^(1 + n) 2^-n)/(7 + 3 (-1)^n)
*)

For large n, only the first two summands remain and we get the asymptotic expression

fsa = (5 + 3 (-1)^n)/(7 + 3 (-1)^n);

To see the limiting values we splitting fsa into terms with even and odd n

fse = Simplify[fsa /. n -> 2 k, k \[Element] Integers]

(* Out[304]= 4/5 *)

fso = Simplify[fsa /. n -> 2 k + 1, k \[Element] Integers]

(* Out[305]= 1/2 *)

And we find thet there are two limiting values, 4/5 and 1/2, for k->[Infinity] so that, strictly speaking, a limit does not exist.

Observations

a) If we would take y^4 instead of y^2 in the numerator of f the function is continuous (have a look at a 3D plot) and the limit is 0.

b) Interestingly, the formal limit of this type

Limit[(3 2^-n)/(7 + 3 (-1)^n), n -> \[Infinity]]

(*
Out[306]= Limit[(3 2^-n)/(7 + 3 (-1)^n), n -> \[Infinity]]
*)

is returned unevaluated. Although, as expected

Limit[Abs[(3 2^-n)/(7 + 3 (-1)^n)], n -> \[Infinity]]

(* Out[307]= 0 *)

Answer 2

In the case you have specified above, there does not exist a unique limit for all sequences $(x_n, y_n) \rightarrow (0,0) \; (n \rightarrow \infty)$. Take for example the following two sequences:

1) $(x_n, 0) \rightarrow (0,0) \; (n \rightarrow \infty)$ with $x_n > 0 \; \forall n$. So we have $(x_n^4 + y_n^2)/(x_n^2 + y_n^2) = x_n^2 \rightarrow 0 \; (n \rightarrow \infty)$.

2) $(0, y_n) \rightarrow (0,0) \; (n \rightarrow \infty)$ with $y_n > 0 \; \forall n$. So we have $(x_n^4 + y_n^2)/(x_n^2 + y_n^2) = 1 \rightarrow 1 \; (n \rightarrow \infty)$.

Obviously the two limits are different, so Limit cannot give you a unique result without specifying further restrictions to the sequence.