4
$\begingroup$

I have the following function

    f = 1/Gamma[(1 + d)/2] \[Pi]^(
  1/2 (-1 + d)) ((
    Sqrt[2] (-1 + d) r^5 (2 + r^(-4 + 2 d)) Hypergeometric2F1[-(1/2), 
      1/(-4 + 2 d), 1 + 1/(-4 + 2 d), -(1/2) r^(-4 + 2 d)])/(
    2 r^4 + r^(2 d)) + (
    r^(-1 + d) (6 - 4 d + (
       Sqrt[2] (2 - 3 d + d^2) r^(
        2 + d) (2 + r^(-4 + 2 d)) Hypergeometric2F1[1/2, (3 - 2 d)/(
         4 - 2 d), (7 - 4 d)/(
         4 - 2 d), -(1/2) r^(-4 + 2 d)])/((-3 + 2 d) (2 r^4 + r^(
          2 d))) + 
       2 (-1 + d) Log[(2 r^d)/(r^d + r^2 Sqrt[2 + r^(-4 + 2 d)])]))/(
    2 (-1 + d)))

Mathematica can not evaluate the limit of $f$ when $r$ goes to infinity.

Limit[f, r -> Infinity, Assumptions -> d >= 4]

Is there anyway that this limit can be evaluated by Mathematica? Note that if I first put $d=4$ or $5$ or ... and then take the limit, Mathematica find the answer.

Limit[f /. d -> 4, r -> Infinity]
-(2/9) 2^(3/4) Sqrt[\[Pi]] (9 Gamma[-(3/4)] + 4 Gamma[1/4]) Gamma[5/4]

But I need the general relation as a function of $d$.

$\endgroup$
3
  • 1
    $\begingroup$ Limit[f, r -> Infinity, Assumptions -> d > 1] results in ConditionalExpression[\[Infinity], d < 3/2] and both Limit[f, r -> Infinity, Assumptions -> d > 3/2 && d \[Element] Integers]andLimit[f, r -> Infinity, Assumptions -> d > 3/2] return the input. $\endgroup$
    – user64494
    Nov 10, 2021 at 9:37
  • 2
    $\begingroup$ Table[Limit[f, r -> Infinity, Assumptions -> d > 1], {d, 2, 7}] results in {\[Infinity], \[Infinity], -(2/9) 2^(3/4) Sqrt[\[Pi]] (9 Gamma[-(3/4)] + 4 Gamma[1/4]) Gamma[5/4], -((\[Pi]^( 3/2) (8 Gamma[-(2/3)] Gamma[7/6] + 25 Gamma[1/3] Gamma[7/6] - 11 Gamma[1/6] Gamma[4/3]))/(4 2^(1/3))), -(2/225) 2^(5/8) \[Pi]^( 3/2) (150 Gamma[-(5/8)] Gamma[9/8] + 513 Gamma[3/8] Gamma[9/8] - 155 Gamma[1/8] Gamma[11/8]), -((\[Pi]^( 5/2) (18 Gamma[-(3/5)] Gamma[11/10] + 65 Gamma[2/5] Gamma[11/10] - 15 Gamma[1/10] Gamma[7/5]))/(18 2^(2/5)))}, so general formula is unclear. $\endgroup$
    – user64494
    Nov 10, 2021 at 9:48
  • $\begingroup$ And such a general formula may not exist. $\endgroup$
    – user64494
    Nov 10, 2021 at 9:56

3 Answers 3

8
$\begingroup$
f[d_, r_] = 1/Gamma[(1 + d)/2] π^(1/2 (-1 + d))((Sqrt[2] (-1 + d) r^5 (2 + r^(-4 + 2 d)) Hypergeometric2F1[-(1/2), 1/(-4 + 2 d), 1 + 1/(-4 + 2 d), -(1/2) r^(-4 + 2 d)])/(2 r^4 + r^(2 d)) + (r^(-1 + d) (6 - 4 d + (Sqrt[2] (2 - 3 d + d^2) r^(2 + d) (2 + r^(-4 + 2 d)) Hypergeometric2F1[1/2, (3 - 2 d)/(4 - 2 d), (7 - 4 d)/(4 - 2 d), -(1/2) r^(-4 + 2 d)])/((-3 + 2 d) (2 r^4 + r^(2 d))) + 2 (-1 + d) Log[(2 r^d)/(r^d + r^2 Sqrt[2 + r^(-4 + 2 d)])]))/(2 (-1 + d)));

F[d_] := F[d] = Limit[f[d, r], r -> ∞]

Table[F[d] == -((2^(1/2 (-3 + 1/(-2 + d))) π^(-1 + d/2) *
                Gamma[-((-1 + d)/(2 (-2 + d)))] *
                Gamma[1/(-4 + 2 d)])/Gamma[(1 + d)/2]), {d, 4, 20}] // FullSimplify
(*    {True, True, True, True, True, True, True, True, True, True, True, True, True, True, True, True, True}    *)

So it looks like the limit is

$$ -\frac{2^{\frac{1}{2} \left(\frac{1}{d-2}-3\right)} \pi ^{\frac{d}{2}-1} \Gamma \left(-\frac{d-1}{2 (d-2)}\right) \Gamma \left(\frac{1}{2 d-4}\right)}{\Gamma \left(\frac{d+1}{2}\right)} $$

$\endgroup$
7
  • 1
    $\begingroup$ Unfortunately, FindSequenceFunction[{-(4/3) 2^(3/4) Sqrt[\[Pi]] Gamma[-(3/4)] Gamma[ 5/4], -((\[Pi]^(3/2) Gamma[-(2/3)] Gamma[1/6])/(4 2^(1/3))), -(2/ 15) 2^(5/8) \[Pi]^(3/2) Gamma[-(5/8)] Gamma[ 1/8], -((5 \[Pi]^(5/2) Gamma[-(3/5)] Gamma[11/10])/(6 2^(2/5)))}, d] returns the input. $\endgroup$
    – user64494
    Nov 10, 2021 at 11:04
  • 2
    $\begingroup$ @user64494 I figured out the Gamma and $\pi$ dependencies manually (by inspection) and then used FindSequenceFunction on the remaining factor. $\endgroup$
    – Roman
    Nov 10, 2021 at 11:25
  • 1
    $\begingroup$ FindSequenceFunction leaves much to be desired. For example, FindSequenceFunction[{-1, 4, -9, 16, -25, 36}, n] returns the input. $\endgroup$
    – user64494
    Nov 10, 2021 at 11:40
  • 1
    $\begingroup$ Nice, this is the correct answer. Pity that MA cannot do it automatically. $\endgroup$
    – yarchik
    Nov 10, 2021 at 13:41
  • 1
    $\begingroup$ Nice answer. Thank you very much. $\endgroup$
    – Kheeyal
    Nov 10, 2021 at 16:21
4
$\begingroup$

Asymptotic evaluates to

asy=Asymptotic[f, r -> Infinity]
(*ConditionalExpression[ ..., 0 < d < 1]*)

and restricts parameter to 0<d<1.

Simplify[asy, 0 < d < 1]
(*(Sqrt[2] (-1 + d) \[Pi]^(1/2 (-1 + d))r)/Gamma[(1 + d)/2]*)

$$ \frac{\sqrt{2} (d-1) \pi ^{\frac{d-1}{2}} r}{\Gamma \left(\frac{d+1}{2}\right)} $$

shows asy~r! The limit doesn't exist for r -> Infinity!

$\endgroup$
2
  • $\begingroup$ Thank you. The assumption is that d>=4. $\endgroup$
    – Kheeyal
    Nov 10, 2021 at 16:09
  • $\begingroup$ Sorry I overlooked the restriction d>= 4 $\endgroup$ Nov 10, 2021 at 18:25
2
$\begingroup$

Using Asymptotic with an assumption about d ought to do the job (as in Ulrich's answer):

Asymptotic[f, r->Infinity, Assumptions->d>4]

But it takes too long. On the other hand, it looks like you can help Mathematica by shifting the d variable:

asym = Asymptotic[
    FullSimplify[f /. d -> z + 4], 
    r -> Infinity, 
    Assumptions -> z > 0
];

Unfortunately, the output still depends on r:

FreeQ[asym, r]

False

However, if you repeat using Asymptotic on the above output:

asym2 = Asymptotic[asym, r->Infinity, Assumptions -> z > 0];

The output no longer depends on r:

FreeQ[asym2, r]

True

Shifting back and simplifying yields:

r = FullSimplify[asym2 /. z -> d - 4]

-((2^(1/2 (-3 + 1/(-2 + d))) π^(-1 + d/2) Gamma[1/(2 (-2 + d))] Gamma[-((-1 + d)/(2 (-2 + d)))])/Gamma[(1 + d)/2])

This is equivalent to Roman's answer:

Simplify @ Equal[
    r,
    -((2^(1/2 (-3+1/(-2+d))) π^(-1+d/2)*Gamma[-((-1+d)/(2 (-2+d)))]*Gamma[1/(-4+2 d)])/Gamma[(1+d)/2])
]

True

$\endgroup$
1
  • $\begingroup$ Nice answer. In my Mathematica version, doesn't work Asymptotic for asym, but taking the limit works well. $\endgroup$ Nov 12, 2021 at 1:23

Your Answer

By clicking “Post Your Answer”, you agree to our terms of service, privacy policy and cookie policy

Not the answer you're looking for? Browse other questions tagged or ask your own question.